Probabilistic model
From: "Leonid Gibiansky" leonidg@metrumrg.com
Subject: [NMusers] Probabilistic model
Date: Fri, May 13, 2005 12:54 pm
Dear All,
I recently worked with the PK/PD model with the categorical 6 level score PD data.
Example of the
code is given below, just to avoid description of the model. The run time was about
an hour, so I
was able to experiment with the model. I used the following procedure:
1. Run the model with some initial conditions
2. Looked on the final estimate and updated the initial conditions according to the
following rule:
new initial parameter value = final estimate * exp(mean eta value). Mean eta
value varied between
0 and 0.3 (exponential eta model) during the first 2-3 iterations and between 0
and 0.15 later on.
3. Run the model with new initial conditions, etc.
After 10 or so iterations, objective function decreased by about 100 points (with
some visible
improvement of the fit), variances of the random effects decreased by 2-3 times. It
looks like the
OF surface is very shallow, with a lot of local minimums that attract the solution.
My question is whether you have seen the same behavior in similar problems, and if
yes, how can we
improve convergence (modify the model?), how to make sure that the final result is
valid? Should
such fine-tuning after convergence be a necessary step of any similar model? Have
you developed any
rules/scripts to automate the process?
Thanks
Leonid
;Model Desc: PK/PD model
$PROB RUN# 005M
$INPUT C = DROP ID TIME AMT DV EVID MDV WT
$DATA data.csv IGNORE=C
$SUBROUTINES ADVAN7 TRANS1
$MODEL
NCOMPS=3
COMP=COMP1; CENTRAL
COMP=COMP2; PERIPH
COMP=COMP3; EFFECT
$PK
;PK
K12=0.0526
K21=0.0241
V1 = 0.73*WT
K10 = 0.0151
; EFFECT COMPARTMENT
KE0=THETA(1)*EXP(ETA(1))
K13=0.001*K10
K31=KE0
V3= K13*V1/K31
; PD
SLOP= THETA(2)*EXP(ETA(2))
EC50= THETA(8)*EXP(ETA(4))
; Baseline odds
B0=THETA(3)*EXP(ETA(3))
B1=B0+THETA(4)
B2=B1+THETA(5)
B3=B2+THETA(6)
B4=B3+THETA(7)
$ERROR
; Drug effect
CE=A(3)/V3
EFF=SLOP*CE/(EC50+CE)
;LOGITS FOR Y<=5,Y<=4, Y<=3, Y<=2, Y<=1, Y<=0
C0=EXP(B0 + EFF)
C1=EXP(B1 + EFF)
C2=EXP(B2 + EFF)
C3=EXP(B3 + EFF)
C4=EXP(B4 + EFF)
;CUMULATIVE PROBABILITIES
P0=C0/(1+C0)
P1=C1/(1+C1)
P2=C2/(1+C2)
P3=C3/(1+C3)
P4=C4/(1+C4)
; P(Y=M)
PR5 = (1 -P4)
PR4 = (P4-P3)
PR3 = (P3-P2)
PR2 = (P2-P1)
PR1 = (P1-P0)
PR0 = P0
IF (DV.LT.0.5) Y=PR0
IF (DV.GE.0.5.AND.DV.LT.1.5) Y=PR1
IF (DV.GE.1.5.AND.DV.LT.2.5) Y=PR2
IF (DV.GE.2.5.AND.DV.LT.3.5) Y=PR3
IF (DV.GE.3.5.AND.DV.LT.4.5) Y=PR4
IF (DV.GE.4.5) Y=PR5
$THETA
...
$OMEGA
.....
$EST MAXEVAL=9999 SIGDIG = 4 METHOD=1 LIKE LAPLACE NUMERICAL NOABORT