From: "Nele Plock" nplock@zedat.fu-berlin.de
Subject: [NMusers] Standard errors below 0.1%?
Date: Wed, 03 Aug 2005 09:41:48 +0200
Dear all,
I have been trying to implement a model for data with both iv and oral dosing. The
control stream is attached below. By using a model with first order absorption I
could get the covariance step to run. However, using a model with zero order absorption
led to a big drop in OF, although the runs terminate due to rounding errors. When I
change the TOLERANCE from 5 to 4 the run is successful and the covariance step as well.
What is weird though is that the highest standard error is estimated to be 0.1%, all
others are even below that value.
Now my questions are as follows:
What exactly does the change in TOL do that leads to a successful run?
Has anybody ever seen standard errors that low? What could be the reason, because
frankly speaking I dont trust those values at all?
Any help would be appreciated!
Nele
;PROJECT: test
;STUDY: iv/po multiple dose
;RUN: 048
;KINETICIST: N. Plock
;NOTES: 2-COMP. MODEL, COMBINED ERROR MODEL
;NOTES: IIV ON K10, V1, V2, D1, CL, zero order absorption, FOCE INT method
$PROBLEM iv/po
$INPUT ID TIME TILD AMT RATE ADMA CMT DV FLMA EVID VIST OCC DAY AGE SEX HT
CID=DROP TYPE=DROP FUPL FLAG
$DATA ivpo_220705_ID01-33 IGNORE=#
$SUBROUTINES ADVAN6 TRANS1 TOL4
$MODEL
NCOMPS=4
COMP=(CENTRAL, DEFOBS)
COMP=(PERIP1)
COMP=(DELAY)
COMP=(ELIM)
$PK
TVK10=THETA(1)
K10=TVK10*EXP(ETA(1))
TVV1=THETA(2)
V1=TVV1*EXP(ETA(2))
TVQ=THETA(3)
Q=TVQ
TVV2=THETA(4)
V2=TVV2*EXP(ETA(3))
TVD1=THETA(5)
D1=TVD1*EXP(ETA(4))
ALAG1=0
IF (ID.EQ.3.AND.OCC.GT.1) ALAG1=THETA(6)
IF (ID.EQ.6.AND.OCC.GT.1) ALAG1=THETA(6)
IF (ID.EQ.9.AND.OCC.GT.1) ALAG1=THETA(6)
TVEC50=THETA(7)
EC50=TVEC50
TVEMAX=THETA(8)
EMAX=TVEMAX
TVKIC=THETA(9)
KIC=TVKIC
TVCL=THETA(10)
CL=TVCL*EXP(ETA(5))
S1=V1
K14=CL/V1
K12=Q/V1
K21=Q/V2
$DES
CLIN=A(1)/V1
DADT(1)=-A(1)*K12+A(2)*K21-A(1)*K10*(1-EMAX*A(3)/(A(3)+EC50))-K14*A(1)
DADT(2) = A(1)*K12 -A(2)*K21
DADT(3) = KIC*(CLIN-A(3))
CL2=K10*(1-EMAX*A(3)/(A(3)+EC50))*V1
$ERROR
IPRED=F
DEL=0
IF (IPRED.EQ.0) DEL=0.0001
W=F
IRES=DV-IPRED
IWRES=IRES/(W+DEL)
Y=IPRED+W*EPS(1)+EPS(2)
;---------------------------------------INITIAL ESTIMATES-----------------------------------
$THETA (0.05,0.14) ; 1 K10
$THETA (0.1,21.2) ; 2 V1
$THETA (0.1,76) ; 3 Q
$THETA (0.1,30) ; 4 V2
$THETA (0.001,1) ; 5 D1
$THETA 1.23 FIX ; 6 ALAG1
$THETA (0.1,0.15) ; 7 EC50
$THETA 1 FIX ; 8 EMAX
$THETA (0.001,0.005) ; 9 KIC
$THETA (0.1,7.5) ; 10 CL
$OMEGA 5 ; 1 IIV_K10
$OMEGA 0.15 ; 2 IIV_V1
$OMEGA 0.1 ; 3 IIV_V2
$OMEGA 0.4 ; 4 IIV_D1
$OMEGA 0.3 ; 5 IIV_CL
$SIGMA 0.01 ; prop.error
$SIGMA 0.1 ; add. error
$ESTIMATION PRINT=5 METHOD=1 INTERACTION MSFO=msf MAXEVAL=9999 NOABORT
$COV
$TABLE ID TIME IPRED IWRES ONEHEADER NOPRINT FILE=sdtab
$TABLE ID ETA1 ETA2 ETA3 ETA4 ETA5 K10 V1 Q K14 V2 D1 ALAG1 EC50 EMAX KIC CL
CL2 Q FLAG ONEHEADER NOPRINT FILE=patab
Standard errors below 0.1%?
From: "Bachman, William (MYD)" bachmanw@iconus.com
Subject: RE: [NMusers] Standard errors below 0.1%?
Date: Wed, 3 Aug 2005 08:05:29 -0400
Changing the TOL effectively changes the search over the response surface
(lowering the tolerance allows termination with less stringent criteria)
which, as in your case, can result in a successful covariance step.
As far as the standard error estimates, one should use all the information
at hand to assess the the model including the variance estimates and
diagnostic plots. Are the low std error estimates corroborated by tight
plots or, conversely, are they all over the place. (That information is
really more related to the variance estimates, but, if you have highly
informative data you will get low std error estimates).
I haven't looked at your model thoroughly and without assessing all the
estimates and seeing diagnostic plots, it's difficult to know if your std
estimates should be trusted. However, it's UNUSUAL for Michaelis-Menten
type parameters to be well estimated.
From: Leonid Gibiansky leonidg@metrumrg.com
Subject: RE: [NMusers] Standard errors below 0.1%?
Date: Wed, 03 Aug 2005 09:15:38 -0400
I've seen these SE once. To me this is an indication that R or S matrix (or both)
have zero or nearly zero eigenvalue(s). Inverse zero is infinity, this infinity "spreads
out" over all eigenvalues. The next inverse leads to zeros, and not only in the original
"zero-direction" but also in all other eigenvalues.
Try MATRIX=S (or MATRIX=R) on the $COV step to see whether this change the result.
Try SIGDIGITS=5 (or 5, 6) on the estimation step instead of (or in addition to) changing TOL
Log-transformation of DV (that is not directly related to the problem but helpful
for stability of the model) solved my problem that time.
Leonid
_______________________________________________________