From: Paul Hutson <prhutson@pharmacy.wisc.edu>
Subject: Non-zero peripheral drug amount
Date: Tue, 02 Oct 2001 16:10:04 -0500
I am trying to determine if calculated tissue concentrations of topotecan affect had an impact upon response or toxicity.
I have set up a control stream (below) with $DES that is used to generate values for the peripheral compartment (A(2)). The run converges at reasonable parameters, but the table with output of A(2) has a non-zero amount of drug in the peripheral compartment at the beginning of the dose. The sampling is repeated 6 weeks later, and in this case the starting amount in A(2) is zero. I've added the first patient's data set. Does anyone see why A(2) at time =0 for the first infusion should be a non-zero number? I have tried using EVID = 3
$PROBLEM TOPOTECAN 20
; NONRENAL CL, V1, V2 f(DWGT)
$INPUT ID DATE=DROP TIME DV AMT RATE ADDL II WGT HT AGE SCR GEN EVID
$DATA TOPOXRT1.TXT IGNORE=C
$SUBROUTINE ADVAN6 TOL=3
$MODEL NCOMP=2 COMP=(CENTRAL,DEFDOS,DEFOBS) COMP=(PERIPH)
$PK
BSA=(HT*WGT/3600)**0.5; CALCULATES BSA
THT=(HT-152.4)/2.54; CALCS HT ABOVE 5FT (IN CM)
IBW=45 - 5*(GEN-1)+(2.3*THT); CALCS "IDEAL BODY WT" BY GENder (M=0; F=1)
DWGT=IBW
IF(IBW.GT.WGT) DWGT=WGT;
;USES ACTUAL WGT IF < IDEAL WGT
;CALCS CREATININE CLEARANCE
TAGE=140-AGE
CLCR=(TAGE*WGT*0.85**GEN)/(72*SCR); ESTIMATED CLCR BASED UPON ACTUAL WEIGHT
CCLCR=(TAGE*IBW*0.85**GEN)/(72*SCR); USING IBW RATHER THAN ACTUAL WT
;IF(LVL=1)
TVCLR=THETA(1)
CLR=TVCLR*EXP(ETA(1))*CLCR/100; RENAL, 100 TAKEN AS USUAL CLCR
TVCLNR=THETA(2)*DWGT
CLNR=TVCLNR*EXP(ETA(2)); NONRENAL
CL=CLR+CLNR
TVV1=THETA(3)*DWGT
V1=TVV1*EXP(ETA(3));
TVQ=THETA(4)
Q=TVQ*EXP(ETA(4));
TVV2=THETA(5)*DWGT
V2=TVV2*EXP(ETA(5))
K10=CL/V1
K12=Q/V1
K21=Q/V2
S1=V1
IF (ABS(ETA(1)).GT.10) EXIT 1 100
IF (ABS(ETA(2)).GT.10) EXIT 1 200
IF (ABS(ETA(3)).GT.10) EXIT 1 300
IF (ABS(ETA(4)).GT.10) EXIT 1 400
IF (ABS(ETA(5)).GT.10) EXIT 1 500
$ERROR
FX=0
IF (F.EQ.0) FX=1
W=F+FX
IPRED=F
IRES=DV-IPRED
IWRES=IRES/W
Y=IPRED+W*EPS(1)
$THETA (0.01,1,1000); CLRENAL
$THETA (0.0001,0.1,1000); CLNONRENAL
$THETA (0.001,1.5,1000); V1
$THETA (0.001,1.5,1000); Q
$THETA (0.001,50,1000); V2
$OMEGA 1 1 1 1 1
$SIGMA .25
$DES
DADT(1)=-(K10+K12)*A(1)+K21*A(2)
DADT(2)=K12*A(1)-K21*A(2)
X1=A(1); AMT IN CENTRAL COMPARTMENT
X2=A(2); AMT IN PERIPHERAL COMPT
$EST MAXEVAL=4000 POSTHOC NSIG=3 PRINT=10 METHOD=0 NOABORT
$COV
$TABLE ID TIME IPRED IWRES NOPRINT ONEHEADER FILE=sdtab20.txt
$TABLE ID CL V1 Q V2 X2 ETA1 ETA2 ETA3 ETA4
ETA5 NOPRINT ONEHEADER FILE=patab20.txt
$TABLE ID WGT HT BSA AGE CLCR CCLCR GEN NOPRINT ONEHEADER FILE=cotab20.txt
$TABLE ID TIME PRED X2 NOPRINT ONEHEADER FILE=AUCDATA20.TXT
Data file (abbreviated) TOPOXRT1.TXT
C ID,DATE,TIME,DV,AMT,RATE,ADDL,II,WT,HT,AGE,SCR,GEN,EVID
1,03/13/95,09:30,.,350,656.25,4,24,59.9,177.8,55,0.6,0,4
1,03/13/95,10:03,2.3,.,.,.,.,59.9,177.8,55,0.6,0,0
1,03/13/95,10:35,1.3,.,.,.,.,59.9,177.8,55,0.6,0,0
1,03/13/95,11:35,1.0,.,.,.,.,59.9,177.8,55,0.6,0,0
1,03/13/95,12:03,0.8,.,.,.,.,59.9,177.8,55,0.6,0,0
1,03/13/95,13:03,0.6,.,.,.,.,59.9,177.8,55,0.6,0,0
1,03/13/95,14:00,0.5,.,.,.,.,59.9,177.8,55,0.6,0,0
1,03/13/95,15:02,0.3,.,.,.,.,59.9,177.8,55,0.6,0,0
1,04/17/95,09:10,.,350,700,4,24,59.9,177.8,55,0.6,0,1
1,04/17/95,09:45,14.6,.,.,.,.,59.9,177.8,55,0.6,0,0
1,04/17/95,09:50,4.8,.,.,.,.,59.9,177.8,55,0.6,0,0
1,04/17/95,10:18,2.8,.,.,.,.,59.9,177.8,55,0.6,0,0
1,04/17/95,11:12,2.1,.,.,.,.,59.9,177.8,55,0.6,0,0
1,04/17/95,11:42,1.6,.,.,.,.,59.9,177.8,55,0.6,0,0
1,04/17/95,12:45,1.2,.,.,.,.,59.9,177.8,55,0.6,0,0
1,04/17/95,13:37,0.8,.,.,.,.,59.9,177.8,55,0.6,0,0
1,04/17/95,14:40,0.6,.,.,.,.,59.9,177.8,55,0.6,0,0
TABLE NO. 4 AUCTOPO20.TXT
ID TIME X2 DV PRED RES WRES
1.0000E+00 0.0000E+00 6.2590E+01 0.0000E+00 0.0000E+00 0.0000E+00 0.0000E+00
1.0000E+00 5.5000E-01 9.0577E+01 2.3000E+00 8.3474E+00 -6.0474E+00 1.0209E+00
1.0000E+00 1.0800E+00 1.1248E+02 1.3000E+00 1.4657E+00 -1.6573E-01 8.7022E-01
1.0000E+00 2.0800E+00 7.7681E+01 1.0000E+00 6.5279E-01 3.4721E-01 7.4096E-01
1.0000E+00 2.5500E+00 6.4157E+01 8.0000E-01 5.9276E-01 2.0724E-01 8.5609E-01
1.0000E+00 3.5500E+00 4.2671E+01 6.0000E-01 4.9269E-01 1.0731E-01 6.8998E-01
1.0000E+00 4.5000E+00 2.8964E+01 5.0000E-01 4.1392E-01 8.6084E-02 3.5720E-01
1.0000E+00 5.5300E+00 1.9028E+01 3.0000E-01 3.4268E-01 -4.2681E-02 4.2396E-01
1.0000E+00 8.3967E+02 0.0000E+00 0.0000E+00 0.0000E+00 0.0000E+00 0.0000E+00
Paul Hutson, Pharm.D.
Associate Professor (CHS)
UW School of Pharmacy
NOTE NEW ADDRESS effective 6/2001
777 Highland Avenue
Madison, WI 53705-2222
Tel: (608) 263-2496
FAX: (608) 265-5421
Pager: (608) 265-7000, #7856
Non-zero peripheral drug amount
From: Nick Holford <n.holford@auckland.ac.nz>
Subject: Re: Non-zero peripheral drug amount
Date: Wed, 03 Oct 2001 10:18:54 +1200
Paul,
You should have noticed this WARNING from NM-TRAN:
(WARNING 48) DES-DEFINED ITEMS ARE COMPUTED ONLY WHEN EVENT TIME
INCREASES. E.G., DISPLAYED VALUES ASSOCIATED WITH THE FIRST EVENT RECORD
OF AN INDIVIDUAL RECORD ARE COMPUTED WITH (THE LAST ADVANCE TO) AN EVENT
TIME OF THE PRIOR INDIVIDUAL RECORD.
When you save X2 in the TABLE file NONMEM is getting the value from the last time of the previous individual record.
A cleaner way of getting the amount in A(2) is to obtain it in $ERROR e.g.
X2=A(2)
This value will be guaranteed to be the solution of DADT(2) at TIME=0 for that individual.
There is also no need to use $DES. You can use ADVAN3 and get the amount in compartment 2 in $ERROR from the A(2) array as I have indicated above.
BTW Where did you get the formula you use for BSA? This is not the usual duBois and duBois formula.
> BSA=(HT*WGT/3600)**0.5; CALCULATES BSA
Nick
--
Nick Holford, Divn Pharmacology & Clinical Pharmacology
University of Auckland, 85 Park Rd, Private Bag 92019, Auckland, New Zealand
email:n.holford@auckland.ac.nz tel:+64(9)373-7599x6730 fax:373-7556
http://www.phm.auckland.ac.nz/Staff/NHolford/nholford.htm
From: Kazimierz <khkoz@czd.waw.pl>
Subject: Re: Non-zero peripheral drug amount
Date: Wed, 03 Oct 2001 16:45:44 +0200
Dear Professor Holford,
I have used this formula for modelling Vd of Ganciclovir in newborns and infants (Kozlowski KH et al. PAGE2001) and have >10 years experiences.
BSA(m2)=(HT(cm)*WGT(kg))**0.5/60
it uses geometric mean of HT and WGT
Alternative option for inches also exists.
References:
Mosteller RD.N.Engl.J.Med. 317(17), 1098, 1987 - original
Lam TK et. al.: -//- 318(17), 1130, 1988
Clin Pharmacol. Ther. 69, 145-57, 2001 - application for PK
Sincerely Kazimierz H. Kozlowski, Warsaw, Poland
From: Paul Hutson <prhutson@pharmacy.wisc.edu>
Subject: Re: Non-zero peripheral drug amount - solution
Date: Wed, 03 Oct 2001 09:53:31 -0500
Nick:
Thanks. It ran well and A(2) was indeed 0 predose. Ran faster without
ADVAN 6 and DES as well. Sorry to have bothered everyone; I thought I
needed $DES to define A(2).
WRT the BSA equation, This is from Mosteller RD. Simplified calculation of
body-surface area. NEJM 1987; 317: 1098. Works very well in adults and
children - much easier to remember on the wards for dosing chemo. Ht and
Wt are in centimeters and kilograms, actual body weight is used. Let me
know if you would like a pdf copy of the paper.
Thanks again for your suggestion - it saved a great deal of frustration.
Paul
Paul Hutson, Pharm.D.
Associate Professor (CHS)
UW School of Pharmacy
NOTE NEW ADDRESS effective 6/2001
777 Highland Avenue
Madison, WI 53705-2222
Tel: (608) 263-2496
FAX: (608) 265-5421
Pager: (608) 265-7000, #7856