From: Toufigh Gordi tgordi@buffalo.edu
Subject: [NMusers] Different population estimates
Date: 11/17/2003 10:26 AM
Dear all,
I have run a PK/PD model, estimating all parameters simultaneously.
The PK model is a 2-comp with non-linear CL and the PD model is an
E-max model. The final run works very well (FOCE) and gives very
reasonable parameter estimates. The data is rich (>20/subject)
and is from 6 subjects in 6 different dose cohorts (total 36).
What I don't really understand is that the population predictions
(PRED) are different for within the same dose group. I expected to
see identical estimations for subjects receiving the same dose. The
estimates are very close to each other, but they are not identical.
I am thinking that since PK and PD parameters are estimated at the
same time, they do affect each other and thus each subject is its own
"population" and hence the differences. Am I correct or is there any
other explanation?
Thank you,
Toufigh Gordi
Different population estimates
From: Leonid Gibiansky lgibiansky@emmes.com
Subject: Re: [NMusers] Different population estimates
Date: 11/17/2003 11:17 AM
Can it be that subjects in the same dose cohort got different doses
(e.g., WT-proportional dosing or actual dose versus scheduled dose
difference or infusion with different actual duration) ? If not, you
should have exactly the same population estimates.
Leonid.
From: Toufigh Gordi tgordi@buffalo.edu
Subject: Re: [NMusers] Different population estimates
Date: 11/17/2003 11:27 AM
Dear Leonid,
Doses were given as mg/kg and all the parameters are estimated on the
kg/basis. In the data file, subjects within the same dose group
get the same dose.
The model file is given below, in case there are any mistakes I am
making. I am assuming PRED is the population PK.
Toufigh
$SUBROUTINE ADVAN6 TRANS1 TOL=5
$MODEL NCOMP=2
COMP=CENT
COMP=PERIPH
$PK
VM=THETA(1)*EXP(ETA(1))
KM=THETA(2)
V1=THETA(3)*EXP(ETA(2))
Q=THETA(4)
V2=THETA(5)*EXP(ETA(3))
D1=DUR
S1=V1
BASE=THETA(6)*EXP(ETA(4))
IMAX=THETA(7)
IC50=THETA(8)*EXP(ETA(5))
HILL=THETA(9)
$DES
CON=A(1)/V1
DADT(1)=-A(1)*(VM/(KM+CON))/V1-A(1)*Q/V1+A(2)*Q/V2
DADT(2)=A(1)*Q/V1-A(2)*Q/V2
$ERROR
CONC=F
LAM=BASE-(IMAX*(CONC**HILL)/(IC50**HILL+(CONC**HILL)))
IF (PKPD.EQ.2) THEN
Y=LAM*(1+EPS(1))+EPS(2)
ELSE
Y=CONC*(1+EPS(3))+EPS(4)
ENDIF
$THETA (0, 7.02) ;1 VM
$THETA (0, 10.6) ;2 KM
$THETA (0, 4.42) ;3 V1
$THETA (0, 0.456) ;4 Q
$THETA (0, 33.7) ;5 V2
$THETA (0, 60.5, 100) ;6 BASE
$THETA (0, 56.6) ;7 IMAX
$THETA (0, 1.15) ;8 IC50
$THETA (0, 2) ;9 HILL
$OMEGA 0.07 ;1 IIV VM
$OMEGA 0.02 ;2 IIV V1
$OMEGA 0.12 ;3 IIV V2
$OMEGA 0.1 ;4 IIV BASE
$OMEGA 1 ;5 IIV IC50
$SIGMA 0.1 ;1 PROP ERROR PD
$SIGMA 1 ;2 ADD ERROR PD
$SIGMA 0.2 ;3 PROP ERROR PK
$SIGMA 0.1 ;4 ADD ERROR PK
$ESTIMATION NOABORT POSTHOC MAXEVAL=9999 PRINT=3 METHOD=1 MSFO=MSF1
$COVARIANCE
$TABLE ID TIME Y PKPD CONC NOPRINT ONEHEADER FILE=SDTAB1
$TABLE ID TIME BASE IMAX IC50 HILL VM KM V1 Q V2
NOPRINT ONEHEADER FILE=PATAB1
From: Leonid Gibiansky lgibiansky@emmes.com
Subject: Re: [NMusers] Different population estimates
Date: 11/17/2003 11:55 AM
Dear Toufigh,
Have you checked that they also have the same DUR in the data file ?
Also, it is better to add INTERACTION into your estimation step:
$ESTIMATION NOABORT POSTHOC MAXEVAL=9999 PRINT=3 METHOD=1 INTERACTION MSFO=MSF1
Leonid
From: Toufigh Gordi tgordi@buffalo.edu
Subject: Re: [NMusers] Different population estimates
Date: 11/17/2003 2:32 PM
The duration is the same for all. When I run the PK model alone, i.e.
estimated PK parameters in a separate model, population predictions are
exactly the same for individuals in each dose cohort. I also notice from
a couple of subjects that their (predicted) PK profile is slightly changed
depending on if it is generated by the final model (simultaneous PK/PD) or
PK model alone. I find it quite natural since there should be some PK
information in PD data and that is why I estimate all parameters simultaneously.
I will add INTERACTION in the model. Thanks for the suggestion.
Toufigh
From: Leonid Gibiansky lgibiansky@emmes.com
Subject: Re: [NMusers] Different population estimates
Date: 11/17/2003 2:43 PM
My only remaining idea is that PD time points are not the same for the
subjects in the same cohort; this forces NONMEM to evaluate PRED in
different (between subjects) time points, and leads to changes in integration
steps along the way. To check this you may add EVID=2 time points to make
sure that the sets of time points for all subjects in the same cohort are identical.
Simultaneous fit may change PK profile, but should not lead to differences
between population predictions for subjects with the same dose, duration, etc.
Leonid
From: Nick Holford n.holford@auckland.ac.nz
Subject: Re: [NMusers] Different population estimates
Date: 11/17/2003 2:53 PM
Toufigh,
You said the differences in PRED at the same dose for different subjects
were small. This might be explained by numerical errors produced by the
DE solver. The path taken by the solver may be different if the output
times differ from subject to subject. You could try changing TOL and/or
try using ADVAN9 to see if this altered the discrepancy.
You might also consider changing the $DES code to make it computationally
more efficient and IMHO easier to read. There is no need to repeatedly
divide A(1)/V1 and A(2)/V2 when it can be done once.
$DES
CON1=A(1)/V1
CON2=A(2)/V2
DADT(1)=CON2*Q - CON1*(VM/(KM+CON1) + Q)
DADT(2)=Q*(CON1-CON2)
Nick
--
Nick Holford, Dept Pharmacology & Clinical Pharmacology
University of Auckland, 85 Park Rd, Private Bag 92019, Auckland, New Zealand
email:n.holford@auckland.ac.nz tel:+64(9)373-7599x86730 fax:373-7556
http://www.health.auckland.ac.nz/pharmacology/staff/nholford/
From: Toufigh Gordi tgordi@buffalo.edu
Subject: Re: [NMusers] Different population estimates
Date: 11/25/2003 9:26 AM
Dear Leonid and Nick,
Thanks for your comments and suggestions. I thought you might be interested
to know the results of applying the suggested remedies. I could not get the
model to converge using ADVAN8 and 9. My suspicion was that the HILL
parameter caused the problem so I took it out and also added INTERACTION.
It works well. Parameter estimates are similar to those from the old model.
Population values are identical for individuals within each dosing group.
OFV is decreased significantly (from 7538 to 7422) albeit reduction of model
parameters by 1. Can one compare the value between FOCE and FOCE INTERACTION?
Thank you again!
Toufigh Gordi
_______________________________________________________