Re: likelihood model for missing SEX data
From: Nick Holford n.holford@auckland.ac.nz
Subject: Re: [NMusers] likelihood model for missing SEX data
Date: den 4 juli 2006 08:09
Anthe,
A simple way to predict the missing SEX values in your model is to use a mixture model (see below).
This avoids the need to estimate from continuous and non-continuous data. You need to code
SEX with a negative number in the data when it is missing.
If you want to use the continuous and non-continuous joint likelihood method then I recommend
you dont try to code -2LL in $ERROR. In my experience this is less robust and more biased than
using a user defined CCONTR and CONTR (see the contodd example in
ftp://ftp.globomaxnm.com/Public/nonmem/continuous&categorical/).
Andy Hooker recently pointed out to me that this may be because the $ERROR method does not
recognize the covariance among observations that is included by NONMEM when it computes -2LL.
Best wishes,
Nick
;Model Desc: base model run 1 additive residual error
;Project Name: example1
;Project ID: GM00-001
$PROB RUN# 115 (PHENOBARBITAL POPULATION PK MODEL)
$DATA 001SEX.CSV IGNORE=C ; only CONC DV values
$INPUT C ID TIME AMT WT APGR DV=Z EVID MDV SEX FLAG
$EST MAXEVAL=9999 PRINT=20 NOABORT
METHOD=COND LAPLACE
MSFO=mixedsex.MSF
;$COV
$THETA
(0,0.4,1) ; PFEM
(0, 0.005) ; POP_CL
(0, 1.5) ; POP_V
(0,1.4) ; FFEMCL
(0,2.5) ; SD
$OMEGA
0.16 ; PPV_CL
0.16 ; PPV_V
$SIGMA
1 FIX ; EPS1
$SUBROUTINES ADVAN1
$MIX
NSPOP=2
P(1)=THETA(1)
P(2)=1-THETA(1)
$PK
IF (SEX.GE.0) THEN ; not missing
ISEX=SEX
ELSE
IF (MIXNUM.EQ.1) THEN ; female
ISEX=0
ELSE
ISEX=1
ENDIF
ENDIF
TVCL=THETA(2)*THETA(4)**ISEX
CL=TVCL*EXP(ETA(1))
TVV=THETA(3)
V=TVV*EXP(ETA(2))
K=CL/V
S1=V
TAD=TIME ; for a single dose only
SID=ID
$ERROR
IPRED=F
SD=THETA(5)
Y=IPRED + SD*ERR(1)
$TABLE ID SID TIME TAD IPRED CL ETA(1) SEX FLAG
V ETA(2) WT APGR NOPRINT ONEHEADER FILE=115.TAB
pharmacology/staff/nholford/