RE: logistic regression
From: "Piotrovskij, Vladimir [JanBe]" <VPIOTROV@janbe.jnj.com>
Subject: RE: logistic regression
Date: Mon, 17 Sep 2001 14:05:46 +0200
Charlotte,
It is possible to solve some of your problems in NONMEM. However, the best
way is to apply generalized linear regression using one of the statistical
packages.
With NONMEM, try the following control stream:
$PROB dichotomous response: fixed effect of schedule
$DATA nmd.ssc
$INPUT ID AUC SCHD DV
; schedule coded as 1,2,3, etc.
$PRED
SCHD1 = 0
SCHD2 = 0
SCHD3 = 0
SCHD4 = 0
IF (SCHD.EQ.1) SCHD1 = 1
IF (SCHD.EQ.2) SCHD2 = 1
IF (SCHD.EQ.3) SCHD3 = 1
IF (SCHD.EQ.4) SCHD4 = 1
SLOPE = THETA(1)
E50 = SCHD1*THETA(2)+SCHD2*THETA(3)+SCHD3*THETA(4)+SCHD4*THETA(5)
INT = -LOG(E50) * SLOPE
LOGIT = INT + SLOPE * LOG(AUC) + ETA(1)
A=EXP(LOGIT)
P=A/(1+A)
IF (DV.EQ.1) Y=P
IF (DV.EQ.0) Y=1-P
$THETA
(2 5 7); 1 SIGM
(0 30 50); 2 E50 SCHD=1
(20 50 70); 3 E50 SCHD=2
(40 70 90); 4 E50 SCHD=3 (60 100 200); 5 E50 SCHD=4
$OMEGA .0001
$EST METHOD=COND LAPLACE LIKE MAX=500 PRINT=10
$COV
$TABLE ID AUC SCHD DV FILE=tab.ssc ONEHEADER NOPRINT
I tested it using simulation-fitting. Note that you need sufficient number
of individuals per schedule to identify all the parameters with sufficient
precision. In my simulation I included 20 individuals per schedule and it
was OK.
Best regards,
Vladimir
------------------------------------------------------------------------
Vladimir Piotrovsky, Ph.D.
Research Fellow
Global Clinical Pharmacokinetics and Clinical Pharmacology (ext. 5463)
Janssen Research Foundation
B-2340 Beerse
Belgium
Email: vpiotrov@janbe.jnj.com