From: Jian Xu alanub@yahoo.com
Subject: [NMusers] Con't: fast and slow absorption
Date: Wed, 15 Nov 2006 08:24:45 -0800 (PST)
Dear NONMEM Users,
I just came across the topic: fast and slow absorption
in User archive. ( http://www.cognigencorp.com/nonmem/nm/99may081995.html)
Joachim Grevel suggested another way to code this process:
"I used ADVAN5 with 2 Depot compartments linked by first-order rate constants
to the Central compartment (Compartment 3). It is assumed that DEPOT1 has
availability F1 and that DEPOT2 has availability F2=1-F1. Furthermore, both
Depot compartments have different lag times (ALAG1 and ALAG2) and different
absorption rate constants (K13 and K23). When all these parameters are modelled
simultaneously, one can have two types of absorption occur at the same time or
one can restrict the difference between ALAG1 and ALAG2."
I am not an experienced NONMEM user, and he did not provide code to describe this
two DEPOTs approach. To me, F1 or F2 can not be simply coded as bioavailability
since the central compartment will receive drug from both DEPOT1 (F1) and DEPOT2
(1-F1) (as bioavailability, normally we can just code in $ERROR as Y(1)=A(1)/V1*F)?
Would someone kindly provide some hints to code this process especially when ADVAN5
or 6 used?
Thanks in advance,
Jian
Con't: fast and slow absorption
From: "Mouksassi Mohamad-Samer" mohamad-samer.mouksassi@umontreal.ca
Subject: RE : [NMusers] Con't: fast and slow absorption
Date: Wed, 15 Nov 2006 14:56:39 -0500
Dear Jian,
Use the CMT to put a dose into each depot compartment :
example your total dose is 100 mg
put 100 mg into each dose compartment CMT=1 and CMT=2 in data file then in $PK
F1=THETA(1)
F2=1-THETA(1)
Now you have F1 available dose into the first depot ; example 30 % and 70 % in the second depot.
This assumes that 100 % of your dose is bioavailable and F1 and F2 trick is to divide
the dose between the two absorption components.
see fragment control file below
$SUBR ADVAN6
$MODEL
COMP (FAST)
COMP (SLOW)
COMP (CENTRAL)
$PK
F1=THETA(1)
F2=1-THETA(1)
etc...
$DES
DFAST=A(1)
DSLOW=A(2)
DCP=A(3)/V3
DADT(1)= -KA1*DFAST
DADT(2)= -KA2*DSLOW
DADT(3)= IN - DCP*CL
IN= KA1*DFAST + KA2*DSLOW
DADT(3)= IN - DCP*CL
Hope this helps,
If you have a change-point model ie the two processes are sequential rather than parallel
Search for the presentation bye Joel Owen at ECPAG about this issue.
See also this article to see how to constrain the bioavailibilities should you use an eta on them :
Csajka C, Drover D, Verotta D.
The use of a sum of inverse Gaussian functions to describe the absorption profile of drugs
exhibiting complex absorption.
Pharm Res. 2005 Aug;22(8):1227-35
Samer
Samer MOUKSASSI
PhD candidate universit de montral
From: Sam Liao sliao@pharmaxresearch.com
Subject: RE : [NMusers] Con't: fast and slow absorption
Date: Wed, 15 Nov 2006 15:14:08 -0500
Jian:
Here is an example NONMEM control stream for the pk model you need. Please make sure to
specify CMT=3 for your PK data. You also need one dose event record with CMT=1 and the second
dose event record with CMT=2. The AMT will be the same in both records.
Best regards,
Sam Liao
Pharmax Research
=========================================================
$PROB PHARMACOKINETIC MODEL 1-CMPT WITH ONE SLOW AND ONE FAST ABSORPTION
$INPUT ID TIME DAY AMT CONC=DV CMT AGE WT SEX RACE
$DATA nm.prn IGNORE=#
$SUBROUTINE ADVAN6 TOL=6
$MODEL
NCOMP=3
COMP=(DEPOT1,DEFDOSE)
COMP=(DEPOT2)
COMP=(CENT,DEFOBS)
$PK
TVCL= THETA(1)
TVVD= THETA(2)
TKA1= THETA(3)
TKA2= THETA(4)
TF1 =THETA(5)
TLAG= THETA(6)
CL = TVCL*EXP(ETA(1))
V = TVVD*EXP(ETA(2))
KA1 = TKA1*EXP(ETA(3))
KA2 = TKA2*EXP(ETA(4))
F1 = TF1 *EXP(ETA(5))
IF (F1.GT.1) F1=0.999
F2 = 1 - F1
ALAG1=TLAG + ETA(6)
IF (ALAG1.LE.0) ALAG1=0
ALAG2 = ALAG1
K30 = CL/V
S3 = V
;ODE OF THE DECONJUGATION MODEL
$DES
DADT(1)= -KA1*A(1) ; KA1
DADT(2)= -KA2*A(2) ; KA2
DADT(3)= KA1*A(1) +KA2*A(2)-K30*A(3) ; CP
$ERROR
Y=F*(1+ERR(1)) + ERR(2)
IPRE= F
IRES= DV - IPRE
$THETA
(1,25,100) ;1 CL
(100,400,900) ;2 V
(0.1,.3,5) ;3 KA1
(0.001,.1,.3) ;4 KA2
(0.1,.5,1) ;5 F1
0 FIX ;6 TLAG
$OMEGA
0.1 ;1 VAR IN CL
0.1 ;2 VAR IN V
0.1 ;3 VAR IN KA1
0.1 ;4 VAR IN KA2
0.1 ;5 VAR IN F1
0. FIX ;6 VAR IN TLAG
$SIGMA 0.1 1.0
$EST SIG=3 MAXEVAL=9999 PRINT=5 METHOD=0 POSTHOC NOABORT
$COV
$TABLE ID TIME MDV K30 KA1 KA2 CL V ALAG1 F1 IPRE IRES
ONEHEADER NOPRINT FILE=fit
From: Jian Xu alanub@yahoo.com
Subject: RE : [NMusers] Con't: fast and slow absorption
Date: Wed, 15 Nov 2006 15:01:27 -0800 (PST)
Hi, Sam, Mahesh, and Mouksassi,
Thanks for your quick responses, especially thank you for providing me example
code :'). So, if bioavailability for this drug is also to be estimated, will it be
F3 as in your example? or maybe we need to code it separately (assuming we have
both intravenous and oral datasets)?
Thanks,
Jian
From: Sam Liao sliao@pharmaxresearch.com
Subject: RE : [NMusers] Con't: fast and slow absorption
Date: Wed, 15 Nov 2006 19:35:47 -0500
Hi Jian:
If you need to estimate oral bioavailability, then use F2=theta(7),
and the oral bioavailability will be the sum of F1 and F2.
Best regards,
Sam Liao
Pharmax Research
_______________________________________________________