From: "bvatul" <bvatul@ufl.edu>
Subject: Coadministered drugs (PK-PD)
Date: Mon, 1 Oct 2001 14:40:49 -0400
Hello All
Could somebody advise on this?
I am analysing a sparse data set in which two drugs are co-infused. I
have the data of the plasma concentrations of the two drugs along with
the data of a secondary marker which has a precursor. One of the drugs
say A effects the precursor while drug B effects the secondary marker. I
have the data of the two markers too. Both the drugs follow a two
compartment model (There is no significant effect of drug B on the
pharmacokinetics of Drug A). Could you please share your comments on how
to code the two drug concentrations in NONMEM. I am trying to use an
indirect response model with Smax etc and simultaneously model both the
drugs.
Thanks in advance
Atul
Venkatesh Atul Bhattaram
Post-doctoral fellow
University of Florida
Coadministered drugs (PK-PD)
From: Nick Holford <n.holford@auckland.ac.nz>
Subject: Re: Coadministered drugs (PK-PD)
Date: Tue, 02 Oct 2001 08:06:57 +1200
Atul,
;Set CMT to 1 for Drug A, 2 for Drug B, 5 for precursor and 6 for effect mediator
;Set AMT and RATE for A and B to define the infusions
;Set AMT=1 and RATE=0 for precursor and effect mediator at TIME=0 to initialize these CMTs
$INPUT ID TIME ... CMT AMT RATE ... DV MDV
;Because you want to use an indirect effect model you will need to use PREDPP and one of the DE ADVANs e.g. ADVAN6.
$SUBR ADVAN6 TOL=3
;Set up the model structure:
$MODEL
COMP (DRUGA1) ; central for A
COMP (DRUGA2) ; peripheral for A
COMP (DRUGB1) ; central for B
COMP (DRUGB2) ; peripheral for B
COMP (PRECUR) ; precursor
COMP (MEDIAT) ; mediator
$PK
;assign parameters
V1A=THETA(V1A)
...
; At steady state without drug KIN=KOUT*E0 therefore
E0P=KINP/KOUTP
F5=E0P ; initial conc (E0P) of effect precursor
E0M=E0P*KINM/KOUTM
F6=E0M ; initial conc (E0M) of effect mediator
$DES
C1A=A(1)/V1A
C2A=A(2)/V2B
C1B=A(3)/V1B
C2B=A(4)/V2B
C1P=A(5)
C1M=A(6)
DADT(1)= QA*C2A - (QA+CLA)*C1A
DADT(2)= QA*(C1A - C2A)
DADT(3)= QB*C2B - (QB+CLB)*C1B
DADT(4)= QB*(C1B - C2B)
EA=1-C1A/(C50A+C1A) ; PD model for A
EB=1+C1B/(C50B+C1B) ; PD model for B
; details of precursor and mediator eqns are up to you to figure out
DADT(5)= KINP*EA - KOUTP*C1P ; precursor
DADT(6)= C1P*KINP - KOUT*C1E*EB ; Effect mediator
$ERROR
IF (CMT.EQ.1) THEN
CA=A(1)/V1A
Y=CA*EXP(ERRA)
ENDIF
IF (CMT.EQ.3) THEN
CB=A(3)/V1B
Y=CB*EXP(ERRB)
ENDIF
IF (CMT.EQ.5) THEN
CEP=A(5)
Y=CEP + ERRP
ENDIF
IF (CMT.EQ.6) THEN
CEM=A(6)
Y=CEM + ERRM
ENDIF
--
Nick Holford, Divn Pharmacology & Clinical Pharmacology
University of Auckland, 85 Park Rd, Private Bag 92019, Auckland, New Zealand
email:n.holford@auckland.ac.nz tel:+64(9)373-7599x6730 fax:373-7556
http://www.phm.auckland.ac.nz/Staff/NHolford/nholford.htm