RE: saturable metabolism of 5FU
Dear Markus,
First of all it is contradictory to both assume a fix fraction (FM) of
substance converted to 5FU-H2 and at the same say that hat pathway is
saturable. Given that the alternative pathway isn't saturable in the exact
same way the fraction FM will be dependent on the concentration of 5FU.
If you leave the FM parameter out of the equation for the linear model you
will have the exact same model fit but instead of estimating CL of 5FU-H2
you will estimate a parameter that is equal to CL of 5FU-H2 over FM. This
way you do not need to make any assumption about FM.
;[1] Non saturable elimination of 5FU and formation of 5FU-H2
K10 = 0
K12 = CL1/V1
K20 = CL2/V2
This model can be compare to a few alternative models that corresponds to
different hypothesis regarding saturable metabolism. These models are not
strictly nested hierarchical models but in my mind at least you should still
be able to judge them as if they were that (when KM>>C1 the models are
highly similar).
;[2] Saturable elimination of 5FU --> 5FU-H2 (alternative elimination path)
C1 = A(1)/S1
DADT(1) = -C1*VM/(KM+C1)
DADT(2) = C1*VM/(KM+C1)-K20*A(2)
;[3] Saturable metabolism of 5FU --> 5FU-H2 and an alternative non-saturable
elimination path for 5FU.
CL1A = THETA(6)*EXP(ETA(6)) ; Alternative elimination path CL for
5FU
K10 = CL1A/V
C1 = A(1)/S1
DADT(1) = -C1*VM/(KM+C1) -K10*A(1) ; Same as: -C1*VM/(KM+C1) -CL1A*C1
DADT(2) = C1*VM/(KM+C1)-K20*A(2)
; FM = (C1*VM/(KM+C1))/(CL1A*C1) ; FM as a function of C1
;[4] Non-saturable metabolism of 5FU --> 5FU-H2 and an alternative saturable
elimination path for 5FU.
CL1M = THETA(6)*EXP(ETA(6)) ; CL1M
K10 = CL1M/V
C1 = A(1)/S1
DADT(1) = -C1*VM/(KM+C1) -K10*A(1) ; Same as: -C1*VM/(KM+C1) -CL1M*C1
DADT(2) = K10*A(1)-K20*A(2)
; FM = (CL1M*C1)/(C1*VM/(KM+C1)) ; FM as a function of C1
;[5] Non-saturable metabolism of 5FU --> 5FU-H2 and an saturable elimination
of 5FU-H2.
C2 = A(2)/S2
DADT(1) = -K10*A(1)
DADT(2) = K10*A(1) -C2*VM/(KM+C2)
The above scenarios [2-5] can further be combined to account for more than I
saturable elimination path.
For running the differential eq. models I would recommend looking into
ADVAN13 that in my experience is the best performing differential eq. solver
in NONMEM and settings for TOL, SIGL and SIGN (see NONMEM 7 userguide).
Kind regards,
Martin Bergstrand, PhD
Pharmacometrics Research Group
Dept of Pharmaceutical Biosciences
Uppsala University
Sweden
[email protected]
Visiting scientist:
Mahidol-Oxford Tropical Medicine Research Unit,
Bangkok, Thailand
Phone: +66 8 9796 7611
Quoted reply history
From: [email protected] [mailto:[email protected]] On
Behalf Of markus joerger
Sent: den 19 maj 2012 04:23
To: [email protected]
Subject: [NMusers] saturable metabolism of 5FU
dear Community,
I am modeling 5FU --> 5FU-H2, that is potentially saturable. The linear
model runs smoothly, with a fixed proportion of 85% of the parent going to
the metabolite. I wonder how the coding should be if I introduce saturable
metabolism from 5FU to 5FU-H2. This model does not minimize. Should the
coding for saturable metabolism (again with a 85% proportion going from 5FU
to 5FU-H2) look like: ?
V1=THETA(1)*EXP(ETA(1))
VM=THETA(2)*EXP(ETA(2))
KM=THETA(3)*EXP(ETA(3))
CL2=THETA(4)*EXP(ETA(4))
V2=THETA(5)*EXP(ETA(5))
S1=V1/1000
S2=V2/1000
FM=0.85
K20=CL2/V2
$DES
C1=A(1)/S1
C2=A(2)/S2
DADT(1)=-C1*VM/(KM+C1)
DADT(2)=C1*FM*VM/(KM+C1)-K20*A(2)
LINEAR MODEL:
----------------------------------------------------------------------------
--------------------------------------------------------
$INPUT C=DROP ID OCC TIME AMT RATE DV CMT MDV EVID AGE SEX HEP OXA
IRI BEV WT BSA ECOG A496G DPD4 DPD5 CCL
$DATA 08088_6.CSV IGNORE=C
$SUBROUTINES ADVAN5
$MODEL COMP=(CENTRAL, DEFDOSE)
COMP=(5FUH2)
$ABBREVIATED DERIV2=NOCOMMON
$PK
FLAG1=0
FLAG2=0
IF(OCC.EQ.1) FLAG1=1
IF(OCC.EQ.2) FLAG2=2
TVCL1=THETA(1)*THETA(5)**SEX
CL1=TVCL1*EXP(ETA(1)+FLAG1*ETA(2)+FLAG2*ETA(3))
V1=THETA(2)*EXP(ETA(4))
TVCL2=THETA(3)*THETA(6)**SEX
CL2=TVCL2*EXP(ETA(5))
V2=THETA(4)*EXP(ETA(6))
S1=V1/1000
S2=V2/1000
FM=0.85
K10=(1-FM)*CL1/V1
K12=FM*CL1/V1
K20=CL2/V2
$ERROR CALLFL=0
IPRE=-3
IF(F.GT.0) IPRE=LOG(F)
PROP=0
IF(CMT.EQ.1)PROP=EPS(1)
IF(CMT.EQ.2)PROP=EPS(2)
Y=LOG(F)+PROP
W=LOG(F)
IRES=DV-IPRE
IWRES=IRES/W
$THETA
(0, 152) ;CL1
(0, 43.3) ;V1
(0, 144) ;CL2
(0, 122) ;V2
(0,1) ;SEX > CL-5FU
(0,1) ;SEX > CL-5FU-H2
$OMEGA
0.04 ;IIV CL1
$OMEGA BLOCK(1)
0.004 ;IOV OCC1; CL-5FU
$OMEGA BLOCK(1) SAME ;IOV OCC2; CL-5FU
$OMEGA
0.04 ;IIV V1
0.04 ;IIV CL2
0.04 ;IIV V2
$SIGMA
0.329 ;EPS COMP1
0.136 ;EPS COMP2
--
Markus Joerger MD PhD
Associate Professor
Medical Oncology&Clinical Pharmacology
Cantonal Hospital
9007 St. Gallen
Switzerland
[email protected]
[email protected]
Phone: +41-765591070
Fax: +41-714946325