Re: saturable metabolism of 5FU
Marcus,
In the case of first-order elimination of 5FU you can make an assumption of a constant fraction of total 5FU clearance describing the formation of its metabolite. But a constant fraction is not compatible with a mixed order process for formation of a metabolite. As the 5FU conc rises the fraction will decrease because the mixed order clearance to metabolite will decrease while the 5FU clearance by a first-order other process (not to the metabolite) will remain unchanged.
You have to consider estimating another parameter (CLOTHER) describing the other clearance (not to the metabolite) or fixing CLOTHER to zero which assumes all of the parent is converted to metabolite. See NM-TRAN code below.
I prefer to refer to the model predictions by meaningful names rather than use NONMEM's default and essentially meaningless name F. In the code below different names are used for parent and metabolite concs in the $DES and $ERROR blocks because NONMEM does not allow a variable to be created in $DES with the same name as one being created in $ERROR. I like to prefix the $ERROR name with 'D' when I refer to the same quantity in $DES.
Best wishes,
Nick
$PK
VP = THETA(1) ; volume of parent
CLOTHER =THETA(2) ; clearance of parent by first-order other process
VMAX =THETA(3) ; Vmax of parent to metabolite mixed order process
KM =THETA(4) ; Km of parent to metabolite mixed order process
VM = THETA(5) ; volume of metabolite
CLM =THETA(6) ; clearance of metabolite
$DES
DCP =A(1)/VP ; parent i.e. 5FU
DCM =A(2)/VM ; metabolite i.e. 5FU-H2
CLP2M =VMAX/(KM+DCP) ; clearance from parent to metabolite
DADT(1) = - (CLP2M + CLOTHER) *DCP
DADT(2) = CLP2M*DCP - CLM*DCM
$ERROR
CP =A(1)/VP ; This is the same as DCP in the $DES block
CM =A(2)/VM ; This is the same as DCM in the $DES block
IF (CMT.EQ.1) THEN
Y=LOG(CP) + EPS(1)
ENDIF
IF (CMT.EQ.2) THEN
Y=LOG(CM) + EPS(2)
ENDIF
Quoted reply history
On 18/05/2012 11:23 p.m., markus joerger wrote:
> dear Community,
>
> I am modeling 5FU --> 5FU-H2, that is potentially saturable. The linear model runs smoothly, with a fixed proportion of 85% of the parent going to the metabolite. I wonder how the coding should be if I introduce saturable metabolism from 5FU to 5FU-H2. This model does not minimize. Should the coding for saturable metabolism (again with a 85% proportion going from 5FU to 5FU-H2) look like: ?
>
> V1=THETA(1)*EXP(ETA(1))
> VM=THETA(2)*EXP(ETA(2))
> KM=THETA(3)*EXP(ETA(3))
> CL2=THETA(4)*EXP(ETA(4))
> V2=THETA(5)*EXP(ETA(5))
>
> S1=V1/1000
> S2=V2/1000
> FM=0.85
> K20=CL2/V2
>
> $DES
> C1=A(1)/S1
> C2=A(2)/S2
> DADT(1)=-C1*VM/(KM+C1)
> DADT(2)=C1*FM*VM/(KM+C1)-K20*A(2)
>
> LINEAR MODEL:
> ------------------------------------------------------------------------------------------------------------------------------------
> $INPUT C=DROP ID OCC TIME AMT RATE DV CMT MDV EVID AGE SEX HEP OXA
> IRI BEV WT BSA ECOG A496G DPD4 DPD5 CCL
>
> $DATA 08088_6.CSV IGNORE=C
> $SUBROUTINES ADVAN5
> $MODEL COMP=(CENTRAL, DEFDOSE)
> COMP=(5FUH2)
>
> $ABBREVIATED DERIV2=NOCOMMON
>
> $PK
> FLAG1=0
> FLAG2=0
> IF(OCC.EQ.1) FLAG1=1
> IF(OCC.EQ.2) FLAG2=2
>
> TVCL1=THETA(1)*THETA(5)**SEX
> CL1=TVCL1*EXP(ETA(1)+FLAG1*ETA(2)+FLAG2*ETA(3))
> V1=THETA(2)*EXP(ETA(4))
> TVCL2=THETA(3)*THETA(6)**SEX
> CL2=TVCL2*EXP(ETA(5))
> V2=THETA(4)*EXP(ETA(6))
>
> S1=V1/1000
> S2=V2/1000
> FM=0.85
> K10=(1-FM)*CL1/V1
> K12=FM*CL1/V1
> K20=CL2/V2
>
> $ERROR CALLFL=0
> IPRE=-3
> IF(F.GT.0) IPRE=LOG(F)
> PROP=0
> IF(CMT.EQ.1)PROP=EPS(1)
> IF(CMT.EQ.2)PROP=EPS(2)
> Y=LOG(F)+PROP
> W=LOG(F)
> IRES=DV-IPRE
> IWRES=IRES/W
>
> $THETA
> (0, 152) ;CL1
> (0, 43.3) ;V1
> (0, 144) ;CL2
> (0, 122) ;V2
> (0,1) ;SEX > CL-5FU
> (0,1) ;SEX > CL-5FU-H2
>
> $OMEGA
> 0.04 ;IIV CL1
> $OMEGA BLOCK(1)
> 0.004 ;IOV OCC1; CL-5FU
> $OMEGA BLOCK(1) SAME ;IOV OCC2; CL-5FU
> $OMEGA
> 0.04 ;IIV V1
> 0.04 ;IIV CL2
> 0.04 ;IIV V2
>
> $SIGMA
> 0.329 ;EPS COMP1
> 0.136 ;EPS COMP2
>
> --
> Markus Joerger MD PhD
> Associate Professor
> Medical Oncology&Clinical Pharmacology
> Cantonal Hospital
> 9007 St. Gallen
> Switzerland
> [email protected] <mailto:[email protected]>
> [email protected] <mailto:[email protected]>
> Phone: +41-765591070
> Fax: +41-714946325
--
Nick Holford, Professor Clinical Pharmacology
First World Conference on Pharmacometrics, 5-7 September 2012
Seoul, Korea http://www.go-wcop.org
Dept Pharmacology& Clinical Pharmacology, Bldg 505 Room 202D
University of Auckland,85 Park Rd,Private Bag 92019,Auckland,New Zealand
tel:+64(9)923-6730 fax:+64(9)373-7090 mobile:+64(21)46 23 53
email: [email protected]
http://www.fmhs.auckland.ac.nz/sms/pharmacology/holford