Re: Problem with predicted values for peripherial compartment
Hi Istvan,
The issue is that compartment 2 is your default observation (DEFOBS)
compartment. In your $ERROR block, you need something like
IF (CMT.EQ.2) IPRE=A(2)/V2
IF (CMT.EQ.4) IPRE=A(4)/V4
Y=IPRE*(1+ERR(1))+ERR(2)
Note that this will assume the same error structure between the two
compartments which is probably not your intention.
Thanks,
Bill
Quoted reply history
On Apr 22, 2011, at 5:58 AM, Németh István (FGYFK) <[email protected]>
wrote:
>
> Dear Users,
>
> After a succesful estimation of PK data by using ADVAN6 I try to get some
> more detailed predictions for the central and peripherial compartment as
> well. Therefore some "blank" records were inserted to the initial data file,
> like this:
>
> ID AMT EVID TIME DV UVOL CMT MDV
> 1 4e+06 1 0.0 . 0 1 1
> 1 0e+00 0 0.0 0.00000 0 2 0
> 1 0e+00 0 0.0 0.00000 0 4 0
> 1 0e+00 2 0.0 . 0 2 1
> 1 0e+00 2 0.0 0.00000 0 3 0
> 1 0e+00 2 0.0 . 0 4 1
> 1 0e+00 0 0.5 13.93836 0 2 0
> 1 0e+00 0 0.5 44.12349 0 4 0
> 1 0e+00 0 1.0 15.06895 0 2 0
> 1 0e+00 0 1.0 101.76711 0 4 0
> 1 0e+00 2 1.0 . 0 2 1
> 1 0e+00 2 1.0 . 0 4 1
> 1 0e+00 0 2.0 13.14943 0 2 0
> 1 0e+00 0 2.0 108.56616 0 4 0
> 1 0e+00 2 2.0 . 0 2 1
> 1 0e+00 2 2.0 . 0 4 1
> 1 0e+00 2 3.0 . 0 2 1
> 1 0e+00 2 3.0 . 0 4 1
> 1 0e+00 0 4.0 10.92107 0 2 0
> 1 0e+00 0 4.0 117.83321 0 4 0
>
> CMT=2 is the central CMT=4 is a peripherial comparment. The predictions for
> the central compartment were OK, but the predictions for peripherial
> compartment were identical with the central. On the top of this, there were
> no errors with those records where the DV was a measured value.
>
> Is there any idea?
>
> Thanks,
> István
>
> The model:
>
> $PROBLEM
> $INPUT C ID AMT EVID TIME DV UVOL CMT
> $DATA DATANONMEM.CSV IGNORE=C
> $SUBROUTINE ADVAN6 TRANS1 TOL=4
> $MODEL NCOMP=4
> COMP=(DEPOT,DEFDOS)
> COMP=(CENTRAL,DEFOBS)
> COMP=(URINE)
> COMP=(PERIPH)
> $PK
> TVKA=THETA(1)
> TVCL=THETA(2)
> TVCLR=THETA(3)
> TVV2=THETA(4)
> TVKCS=THETA(5)
> TVKSC=THETA(6)
> TVV4=THETA(7)
> KA=TVKA*EXP(ETA(1))
> CL=TVCL*EXP(ETA(2))
> CLR=TVCLR*EXP(ETA(3))
> V2=TVV2*EXP(ETA(4))
> KCS=TVKCS*EXP(ETA(5))
> KSC=TVKSC*EXP(ETA(6))
> V4=TVV4*EXP(ETA(7))
> S2=V2
> S3=UVOL
> S4=V4
> $DES
> DADT(1)=-KA*A(1)
> DADT(2)= KSC*A(4)+KA*A(1)-A(2)*(CLR+CL+KCS)
> DADT(3)= CLR*A(2)
> DADT(4)= KCS*A(2)-KSC*A(4)
> $THETA
> (0,0.1)
> (0,0.1)
> (0,0.1)
> (0,160)
> (0,0.1)
> (0,0.1)
> (0,10)
> $OMEGA
> .1 .1 .1 .1 .1 .1 .1
> $SIGMA
> 0.1 10
> $ERROR
> IPRE=F
> Y=IPRE*(1+ERR(1))+ERR(2)
> $ESTIMATION PRINT=5 METHOD=1 POSTHOC
> $TABLE C ID TIME CMT EVID DV IPRE NOPRINT ONEHEADER FILE=benzopred.tab
>
> István Németh PhD
> Biostatistician
> Developmental Drug Metabolism & Pharmacokinetics
> Pharmacological and Drug Safety Research
> Gedeon Richter Plc
> Tel: 00 36 1 505 7082
> Fax: 00 36 1 889 8526
>
>
>