RE: Problem with predicted values for peripherial compartment
Dear István,
I think one of the problem is that you have defined compartment 2 as the
default observations compartment COMP=(CENTRAL,DEFOBS). If you use the CMT
column it is best to not use either DEFOBS or DEFDOSE.
Furthermore I do not completely understand your model. I have a few
questions/comments:
1) In the dataset it looks as if you have observations from the
peripheral compartment (CMT 4). How is this possible?
2) The way that you have parameterized your model it is not clearances
that you are estimating (more like first order rate constants, but with one
redundant parameter). Below these bullets is an example of how I would
change the code.
3) From my understanding you have three very different kinds of
dependent variable (plasma concentration, urine collection and peripheral
concentration). Even so you assume the same type of residual error for all
of them? I would strongly suggest that you estimate independent residual
error models for the different DVs (also see example below). (It might be
useful to also look into using the L2 data item but that is secondary to
this comment.)
4) The kind of model that you are using does not need to use a
differential equation solver (ADVAN6). It can be estimated with ADVAN5 (or
ADVAN7). The way that I have coded the example below you only need to remove
the $DES section and change the $SUBROUTINE statement if you want to switch
to this faster method.
$PROBLEM
$INPUT C ID AMT EVID TIME DV UVOL CMT
$DATA DATANONMEM.CSV IGNORE=C
$SUBROUTINE ADVAN6 TRANS1 TOL=4
$MODEL NCOMP=4
COMP=(DEPOT)
COMP=(CENTRAL)
COMP=(URINE)
COMP=(PERIPH)
$PK
TVKA = THETA(1)
TVCL = THETA(2)
TVCLR = THETA(3)
TVV2 = THETA(4)
TVQ = THETA(5)
TVV4 = THETA(6)
KA = TVKA*EXP(ETA(1))
CL = TVCL*EXP(ETA(2)) ; Non-renal clearance
CLR = TVCLR*EXP(ETA(3)) ; Renal clearance
V2 = TVV2*EXP(ETA(4)) ; Central distribution volume
Q = TVKCS*EXP(ETA(5)) ; Inter-compartmental clearance
V4 = TVV4*EXP(ETA(6)) ; Peripheral distribution volume
K1T2 = KA
K2T0 = CL/V2
K2T3 = CLR/V2
K2T4 = Q/V2
K4T2 = Q/V4
$DES
DADT(1)=-K1T2*A(1)
DADT(2)= K4T2*A(4) +K1T2*A(1) -(K2T3+K2T0+K2T4)*A(2)
DADT(3)= K2T3*A(2)
DADT(4)= K2T4*A(2) -K4T2*A(4)
$THETA
(0,1)
(0,20)
(0,20)
(0,160)
(0,10)
(0,100)
$OMEGA
.1 .1 .1 .1 .1 .1
$SIGMA
0.1 10 0.1 10 0.1 10
$ERROR
CP = A(2)/V2 ; Plasma concentration
CU = A(3)/UVOL ; Urine concentration
OC4 = A(4)/V4 ; Peripheral concentration?
IPRE = CP ; Individual prediction of plasma
conc.
Y = IPRE*(1+ERR(1))+ERR(2)
IF(CMT.EQ.3) THEN ; For urine collection DV
IPRE = CU
Y = IPRE*(1+ERR(3))+ERR(4)
ENDIF
IF(CMT.EQ.4) THEN ; For Peripheral concentration? DV
IPRE = OC4
Y = IPRE*(1+ERR(5))+ERR(6)
ENDIF
$ESTIMATION PRINT=5 METHOD=1 POSTHOC
$TABLE C ID TIME CMT EVID DV IPRE NOPRINT ONEHEADER FILE=benzopred.tab
Kind regards,
Martin Bergstrand, MSc, PhD student
-----------------------------------------------
Pharmacometrics Research Group,
Department of Pharmaceutical Biosciences,
Uppsala University
-----------------------------------------------
<mailto:[email protected]> [email protected]