RE: PBPK structural model in NONMEM!
Dear Masoud and Guzy,
Thanks for your comments, and sorry for my late reply.
I recode my control stream file and data file, but i'm not quite sure if it
is appropriate. Please correct me if i was wrong! Thanks in advance!
Here is the control stream.
$PROB WBPBPK POPULATION MODEL
$INPUT ID TIME CONC=DV AMT WT EVID CMT MDV
$DATA ..\PBPK.TXT IGNORE=#
$SUBROUTINES ADVAN8 TOL=3
$MODEL
COMP = (LIV,NODOSE) ; 1 - LIVER COMPARTMENT
COMP = (KID,DEFOBS,NODOSE) ; 2 - KIDNEY COMPARTMENT
COMP = (MUS,NODOSE) ; 3 - MUSCLE COMPARTMENT
COMP = (INJ,NODOSE) ; 4 - INJECTIONSITE COMPARTMENT RECEIVING DOSE
COMP = (VEN,NODOSE) ; 5 - VENOUS COMPARTMENT
COMP = (OUT,NODOSE) ; 6 - KIDNEY EXCRETION COMPARTMENT
COMP = (PHSF) ; 7 - FAST PHASE
COMP = (PHSS) ; 8 - SLOW PHASE
COMP = (OTH,NODOSE) ; 9 - OTHER TISSUE
$PK
"FIRST
" COMMON /PRCOMG/ IDUM1,IDUM2,IMAX
" INTEGER IDUM1,IDUM2,IMAX
" IMAX=100000
; ------------------------ TWO ABSORBTION PHASE-------------------- ;
KF = 0.32334 ; FAST PHASE ABSORPTION RATE
KS = 0.0835 ; SLOW PHASE ABSORPTION RATE
; ------------------------- BLOOD FLOWS (Q,L/HR) -------------------- ;
QVEN = 0.25*WT**0.75 ;L/H/KG;
QLIV =QVEN*0.3053;L/H/KG;
QKID =QVEN*0.1398;L/H/KG;
QMUS =QVEN*0.2524 ;L/H/KG;
QINJ = QVEN*0.2524*(0.5/WT) ;L/H/KG;
QOTH=QVEN-QLIV-QKID-QMUS-QINJ
;----------------------------TISSUE VOLUMES (V,L)----------------------;
VLIV =0.0294*WT ;KG;
VKID =0.004*WT ;KG;
VMUS =0.4007*WT ;KG;
VINJ =0.5 ;KG;
VVEN =0.06*WT ;KG;
VOTH=WT-VLIV-VKID-VMUS-VINJ-VVEN
;----------------------------PARTITION COEFFICIENTS-------------------;
PLIV = 1.94
PKID = 2.38
PMUS = 1.11
POTH = 0.05
;---------------------KIDNEY EXCRETION-------------------;
EXCR=(THETA(1))*EXP(ETA(1))
;PLIV=THETA(2)*EXP(ETA(2))
;PKID=THETA(3)*EXP(ETA(3))
;PMUS=THETA(4)*EXP(ETA(4))
;POTH=THETA(5)*EXP(ETA(5))
$DES
;--------------------COMPARTMENT CONCENTRATIONS-------------------;
C1 = A(1)/VLIV ; CONCENTRATION IN LIVER
C2 = A(2)/VKID ; CONCENTRATION IN KIDNEY
C3 = A(3)/VMUS ; CONCENTRATION IN MUSCLE
C4 = A(4)/VINJ ; CONCENTRATION IN INJECTION SITE
C5 = A(5)/VVEN ; CONCENTRATION IN VENOUS
C9 = A(9)/VOTH ; CONCENTRATION IN OTHER TISSUE
DADT(1)=QLIV*(C5-C1/PLIV)
DADT(2)=(QKID*(C5-C2/PKID)-A(2)*EXCR)
DADT(3)=QMUS*(C5-C3/PMUS)
DADT(4)=(KF*A(7)+KS*A(8)+QINJ*(C5-C4/PMUS))
DADT(5)=(QLIV*C1/PLIV+QKID*C2/PKID+QMUS*C3/PMUS+QINJ*C4/PMUS-QVEN*C5)
DADT(6)=EXCR*A(2)
DADT(7)=-KF*A(7)
DADT(8)=-KS*A(8)
DADT(9)=QOTH*(C5-C9/POTH)
$ERROR
Y=A(2)/VKID+EPS(1)
;------------------------INITIAL ESTIMATES------------------------------;
$THETA(0.01,7.12) ; 1-EXCR
;$THETA(1,5.01) ; 2-PLIV
;$THETA(1,3.77) ; 3-PKID
;$THETA(0.2,0.758) ; 4-PMUS
;$THETA(0,0.0889) ; 5-POTH
$OMEGA(0.09) ; 1-EXCR
;$OMEGA(0.09)
;$OMEGA(0.09)
;$OMEGA(0.09)
;$OMEGA(0.09)
;$OMEGA(0.09)
$SIGMA(1) ; 1-ERROR
$EST PRINT=5 MAX=9990 POSTHOC SIGDIG=7 METHOD=0
$COV MATRIX=R
$TABLE ID TIME CONC WT AMT NOPRINT ONEHEADER FILE=PBPK.FIT
Here is part of data file.
#ID TIME CONC AMT WT EVID CMT MDV
1 0 0 492.66 22.3 1 7 1
1 0 0 197.34 22.3 1 8 1
1 24 52.462 0 22.3 0 2 0
2 0 0 492.66 22.4 1 7 1
2 0 0 197.34 22.4 1 8 1
2 72 7.704 0 22.4 0 2 0
Ke, Fang