Re: help with indirect reponse model
Lu,
In addition to Juergen's helpful remarks I would also suggest that you need to
set the initial conditions for your differential equations.
The initial condition for A(3) is presumably SYNTH/LOSS. You can set the
initial state with NONMEM VI as follows:
A_0(3)=SYNTH/LOSS
[Its a bit trickier with NONMEM V -- but why use NONMEM V?]
You could also make the code clearer (IMHO) as follows:
CONC=A(1)/V
RESP=A(3)
IF (CMT .EQ. 1) THEN
Y=CONC*EXP(ERR(1))
ELSE
Y=RESP*EXP(ERR(2))
ENDIF
Nick
Jurgen Bulitta wrote:
>
> Dear Lu,
>
> I think you will get significantly better fits and more meaningful
> parameter estimates, if you do not assume that LOSS=SYNTH.
> SYNTH is an input rate and should have units of response per time
> and LOSS is a first-order rate constant with unit 1/time. These
> are fundamentally different parameters and should not be forced
> to have the same value. The ratio of SYNTH / LOSS determines
> your steady-state baseline in absence of drug which seems to
> be around 5 to 8 in this example.
>
> The compartment value for observation of the PD response
> should probably be CMT.EQ.3 instead of 2.
> IF (CMT .EQ. 2) Q=0
>
> In your inhibition equation, you are assuming that Imax = 1
> INH=IC50/(IC50+A(1)/S1)
>
> You might consider allowing Imax to be less than 1:
> C=A(1)/S1
> INH = 1 - Imax * C / (IC50 + C)
>
> I would consider using the FOCE(+I) method instead of FO
> after you have fixed the current issue.
>
> Hope it helps.
> Best regards
> Juergen
>
> -----------------------------------------------
> Jurgen Bulitta, PhD, Post-doctoral Fellow
> Pharmacometrics, University at Buffalo, NY, USA
> Phone: +1 716 645 2855 ext. 281, [EMAIL PROTECTED]
> -----------------------------------------------
>
> -----Ursprüngliche Nachricht-----
> Von: "Zheng Lu" <[EMAIL PROTECTED]>
> Gesendet: 28.11.07 05:53:19
> An: [email protected]
> CC: [email protected]
> Betreff: [NMusers] help with indirect reponse model
>
> Dear all:
>
> With the following code and data, the predicted fit is poor
> and no standard error output for parameter. I highly appreciate your kind
> help.
> Thanks a lot in your busy time.
>
> $PROB PLK INDIRECT RESPONSE MODEL
> $INPUT ID TIME DV AMT CMT
> $DATA PLKDOSE10SIMUL.CSV IGNORE=C
> $SUBROUTINE ADVAN6 TOL=5
>
> $MODEL
> COMP=(CENTRAL,DEFDOSE)
> COMP=PERIPH
> COMP=EFFECT
>
> $PK
> K10=THETA(1)*EXP(ETA(1))
> V1=THETA(2)*EXP(ETA(2))
> K12=THETA(3)*EXP(ETA(3))
> K21=THETA(4)*EXP(ETA(4))
> SYNTH=THETA(5)*EXP(ETA(5))
> LOSS=SYNTH
> IC50=THETA(6)*EXP(ETA(6))
> S1=V1
>
> $DES
> DADT(1)=K21*A(2)-(K12+K10)*A(1)
> DADT(2)=K12*A(1)-K21*A(2)
> INH=IC50/(IC50+A(1)/S1)
> DADT(3)=SYNTH-LOSS*INH*A(3)
>
> $ERROR
> CP=A(1)/S1
> Q=1
> IF (CMT .EQ. 2) Q=0
> Y=Q*F*EXP(ERR(1))+(1-Q)*F*EXP(ERR(2))
> IPRE=Y
>
> $THETA
> (0,1.3)
> ;K10
> (0,3) ;S1
> (0,0.3) ;K12
> (0,0.37) ;K21
> (0,1)
> ;SYNTH
> (0,10) ;IC50
>
> $OMEGA
> 0 FIX
> 0 FIX
> 0 FIX
> 0 FIX
> 0 FIX
> 0 FIX
>
> $SIGMA
> 0.040
> .5
>
> $ESTIMATION MAXEVAL=9999 POSTHOC PRINT=5
> $COV
> $TABLE
> NOPRINT FILE=PLKPKPD.txt ONEHEADER
> ID TIME AMT CMT CP IPRE
--
Nick Holford, Dept Pharmacology & Clinical Pharmacology
University of Auckland, 85 Park Rd, Private Bag 92019, Auckland, New Zealand
[EMAIL PROTECTED] tel:+64(9)373-7599x86730 fax:+64(9)373-7090
www.health.auckland.ac.nz/pharmacology/staff/nholford