Simulated vs. fitted population concentration curves
From: Toufigh Gordi - tgordi@buffalo.edu
Subject: [NMusers] Simulated vs. fitted population concentration curves
Date: 2/10/2004 10:09 AM
Dear all,
I have been simulating a 2 compartment model with saturable CL. Model
estimates are based on a fit of the same model to real data from subjects
receiving 6 different doses. To my surprise, I find out that concentration
estimates at specific times based on population values differ between the
simulated subject and the real one. I do not understand how this can be the
case. Shouldn't typical concentration-time curves for the simulated and
fitted subjects be the same? The models are given below, first the fitted
model and then the simulated one. THETA values in the simulating model
are, as mentioned above, taken from the fit of the model to real data.
Thank you!
Toufigh Gordi
The fitted model:
---------------------------------------------------------------------------
---------------------------------------------------------------------------
-------------
$PROB ALL DOSES
; 2-COMP
$INPUT ID AMT RATE DUR DATE=DROP TIME DV EVID SEXF CMT GRP PKPD
$DATA finalPK.csv IGNORE=#
$SUBROUTINE ADVAN9 TRANS1 TOL=5
$MODEL NCOMP=2
COMP=CENT
COMP=PERIPH
$PK
VM=THETA(1)*EXP(ETA(1))
KM=THETA(2)
V1=THETA(3)*EXP(ETA(2))
Q=THETA(4)
V2=THETA(5)*EXP(ETA(3))
D1=DUR
S1=V1
$DES
CON=A(1)/V1
DADT(1)=-A(1)*(VM/(KM+CON))/V1-A(1)*Q/V1+A(2)*Q/V2
DADT(2)=A(1)*Q/V1-A(2)*Q/V2
$ERROR
IPRED=F
W=1
IRES=DV-IPRED
IWRES=IRES/W
Y=IPRED*(1+EPS(1))+EPS(2)
$THETA (0, 6.76) ;1 VM
$THETA (0, 7.66) ;2 KM
$THETA (0, 43.4) ;3 V1
$THETA (0, 0.342) ;4 Q
$THETA (0, 46.3) ;5 V2
$OMEGA 0.1 ;1 IIV VM
$OMEGA 0.1 ;2 IIV V1
$OMEGA 0.1 ;3 IIV V2
$SIGMA 0.05 ;3 PROP ERROR PK
$SIGMA 0.1 ;4 ADD ERROR PK
$ESTIMATION NOABORT POSTHOC MAXEVAL=9999 PRINT=3 METHOD=1 INTERACTION
MSFO=MSF2000
$COVARIANCE
$TABLE ID TIME Y PKPD IPRED NOPRINT ONEHEADER FILE=SDTAB2000
$TABLE ID TIME VM KM V1 Q V2 NOPRINT ONEHEADER FILE=PATAB2000
$TABLE ID SEXF NOPRINT ONEHEADER FILE=CATAB2000
---------------------------------------------------------------------------
---------------------------------------------------------------------------
---------------------
The simulated model:
$PROB ALL DOSES
$INPUT ID AMT RATE DUR DATE=DROP TIME DV EVID SEXF CMT GRP PKPD
$DATA popsim.csv IGNORE=#
$SUBROUTINE ADVAN9 TRANS1 TOL=5
$MODEL NCOMP=2
COMP=CENT
COMP=PERIPH
$PK
VM=THETA(1)*EXP(ETA(1))
KM=THETA(2)
V1=THETA(3)*EXP(ETA(2))
Q=THETA(4)
V2=THETA(5)*EXP(ETA(3))
D1=DUR
S1=V1
$DES
CON=A(2)/V1
DADT(1)=-A(1)*(VM/(KM+CON))/V1-A(1)*Q/V1+A(2)*Q/V2
DADT(2)=A(1)*Q/V1-A(2)*Q/V2
$ERROR
IPRED=F
W=1
IRES=DV-IPRED
IWRES=IRES/W
Y=IPRED*(1+EPS(1))+EPS(2)
$THETA (8.41 FIXED) ;1 VM
$THETA (12.3 FIXED) ;2 KM
$THETA (42.3 FIXED) ;3 V1
$THETA (0.367 FIXED) ;4 Q
$THETA (39.5 FIXED) ;5 V2
$OMEGA 0 FIX ;1 IIV VM
$OMEGA 0 FIX ;2 IIV V1
$OMEGA 0 FIX ;3 IIV V2
$SIGMA 0 FIX ;1 PROP ERROR PK
$SIGMA 0 FIX ;2 ADD ERROR PK
$SIMULATION (20031857) ONLYSIM
$TABLE ID TIME IPRED Y PKPD GRP NOPRINT ONEHEADER FILE=SDTAB304