From: musor000@optonline.net
Subject: [NMusers] Wings of NONMEM (WFL)
Date: 3/8/2004 9:45 PM
Hi, Nonmem Users,
I try to install Wings of NONMEM (WFL). Somehing does not work.
When I run nmgo theopt, I am getting "zero" results:
C:\nmvg77\WFN\run>nmgo theopd
Wings for NONMEM
Version 304
c:\nmvg77\tr\.\nmtran.exe theopd.ctl
WARNINGS AND ERRORS (IF ANY) FOR PROBLEM 1
(WARNING 2) NM-TRAN INFERS THAT THE DATA ARE POPULATION.
(WARNING 13) WITH USER-WRITTEN PRED OR $PRED, NM-TRAN CANNOT APPEND THE
MDV DATA ITEM.
g77 -fno-backslash -O -o theopd FSUBS.for c:\nmvg77\nm\.\nonmem.obj c:\nmvg77\nm\.\blkdat.obj c:\nmvg77\nm\.\nonmem.lib
NONMEM theopd...
THETA: POPE0 POPEMAX POPEC50
ETA: ETAE0 ETAEMAX ETAEC50
ERR: ERRSD
theopd.ls ******* eval=0 sig=0 sub= obs=0 CCIL=NNNN
ESTIMATION OMITTED
user 0:2 real 0:2 tcl 0:2
Do you know how to fix the problem?
Thanks!
Pavel Kovalenko
P.S. Here is my wfnauto.bat:
@echo off
if not '%wfnhome%==' goto ospath
rem *******************************
rem Wings for NONMEM Initialization
rem *******************************
rem ******* Check this ************
set WFNHOME=c:\nmvg77\wfn
set NMHOME=c:\nmvg77
set NMHELP=c:\nmvg77\help
set F77HOME=c:\g77
set F77VER=g77
rem ******* Check nmhome sub-dirs match these names ************
rem e.g. set NMNM=nm if c:\nmv\nm
rem or set NMNM=nmd.dir if c:\nmv\nmd.dir
set NMNM=nm
set NMTR=tr
set NMPR=pr
set NMTL=tl
set NMBIN=util
rem ******* Extended WFN only ****
rem Points to NONMEM source file subdirectory
rem under nm, tr, pr, tl NONMEM dirs
rem Default is NMSRC=.
rem set NMSRC=src
set NMSRC=.
:ospath
rem ***** Operating System Path **
if '%OS%=='Other set OS=Windows_NT
set path=c:\windows\command;c:\windows
if '%OS%=='Windows_NT set path=%systemroot%\system32;%systemroot%
rem ******* Other Software ******
rem If you use Crossgraphs then set cghome
rem set CGHOME=c:\belmont
rem If you have installed the full GNU compiler tools
rem you may want to include them in your path by setting GNUPATH
rem to the compiler bin directory. The path is set later in this file.
rem set GNUPATH=c:\nmv\g77\bin
set GNUPATH=c:\g77\bin
rem ******* End Check this ********
if not '%1=='-q goto args2
set tmp_qt=-q
shift
:args2
rem First argument is compiler type e.g. wc, ms, df, g77
if not '%1==' set F77TYP=%1
if '%F77TYP%=='df66a set F77TYP=df
if '%F77TYP%=='df66A set F77TYP=df
if '%F77TYP%=='df66 set F77TYP=df
if '%F77TYP%=='df65 set F77TYP=df
if '%F77TYP%=='df60a set F77TYP=df
if '%F77TYP%=='df60A set F77TYP=df
if '%F77TYP%=='h77 set F77TYP=g77
rem ******* Extended WFN only ****
rem Second argument is name of sub-dir e.g. std
rem with specific compilation object files
if not '%2==' set NMOBJ=%2
rem Typical user does not have named sub-dir therefore NMOBJ should be set to .
if '%nmobj%==' set NMOBJ=.
rem *******************************
:compiler
for %%c in (df g77 ms wc) do if '%f77typ%=='%%c goto %f77typ%
echo Invalid compiler type [%f77typ%]. Please select from g77,df,ms or wc.
goto over
:g77
rem ******* Check this ************
rem set F77HOME=c:\g77
rem ******* End Check this ********
set LIB=
set LIBRARY_PATH=%f77home%\lib
set F77PATH=%f77home%\bin
set F77EXE=g77
set F77OPT=-fno-backslash -O
rem *******************************
if '%nmobj%=='non set F77OPT=-fno-backslash
if '%nmobj%=='std set F77OPT=-fno-backslash -O
if '%nmobj%=='o10 set F77OPT=-fno-backslash -O1
if '%nmobj%=='o1m set F77OPT=-fno-backslash -malign-double -O1
if '%nmobj%=='o20 set F77OPT=-fno-backslash -O2
if '%nmobj%=='o2m set F77OPT=-fno-backslash -malign-double -O2
if '%nmobj%=='o30 set F77OPT=-fno-backslash -O3
if '%nmobj%=='o3m set F77OPT=-fno-backslash -malign-double -O3
goto notwot
:df
rem ******* Check this ************
rem set F77HOME=c:\progra~1\devstu~1
rem Finding F77HOME for the df compiler can be tricky
rem Windows NT or 2K users can use the long name path e.g.
rem c:\Program Files\Microsoft Visual Studio.
rem Windows 95 or 98 users need to find the short name version of the path
rem Find the c:\Program Files folder using the Windows Explorer, right click
rem on the folder then look at Properties for the MS-DOS name.
rem It is usually c:\progra~1
rem Then repeat the process to find the Microsoft Visual Studio folder's MS-DOS name.
rem It might be micros~1, micros~2 or micros~3 or ...
rem f77home is made up of these two MS-DOS names e.g.
rem Typical Short Name and Long Name for Fortran Compiler home directory:
rem Short Name Long Name
rem c:\progra~1\micros~1 C:\Program Files\Microsoft Visual Studio
rem c:\progra~1\devstu~1 C:\Program Files\Development Studio
set DFVERSION=6
rem if you are using DF V 6 then set dfversion=6
rem Version 6 includes Compaq Visual Fortran upgrades e.g. 6.1A
rem if you are using an earlier version then set dfversion=
rem You will have to figure out the paths yourself for other versions
rem ******* End Check this ********
if '%dfversion%=='6 goto dfv6
set LIB=%f77home%\df\lib;%f77home%\vc\lib
set F77PATH=%f77home%\df;%f77home%\df\bin;%f77home%\vc\bin;%f77home%\shared~1\bin
goto check2
:dfv6
set INCLUDE=%f77home%\df98\include
set LIB=%f77home%\df98\lib;%f77home%\vc98\lib
set F77PATH=%f77home%\df98\bin;%f77home%\vc98\bin;%f77home%\common\msdev98\bin
:check2
set F77EXE=df
set F77OPT=/fltconsistency /optimize:4 /fast
rem ********************************
if '%nmobj%=='non set F77OPT=/fltconsistency /optimize:0
if '%nmobj%=='std set F77OPT=/fltconsistency /optimize:4 /fast
if '%nmobj%=='o10 set F77OPT=/fltconsistency /optimize:1
if '%nmobj%=='o20 set F77OPT=/fltconsistency /optimize:2
if '%nmobj%=='o30 set F77OPT=/fltconsistency /optimize:3
if '%nmobj%=='o40 set F77OPT=/fltconsistency /optimize:4
if '%nmobj%=='o50 set F77OPT=/fltconsistency /optimize:5
if '%nmobj%=='o1f set F77OPT=/fltconsistency /optimize:1 /fast
if '%nmobj%=='o2f set F77OPT=/fltconsistency /optimize:2 /fast
if '%nmobj%=='o3f set F77OPT=/fltconsistency /optimize:3 /fast
if '%nmobj%=='o4f set F77OPT=/fltconsistency /optimize:4 /fast
if '%nmobj%=='o5f set F77OPT=/fltconsistency /optimize:5 /fast
rem ********************************
if not '%nmobj%=='. set NMLINK=nmlinkdf
goto nmlink
:ms
rem ******* Check this ************
set F77HOME=c:\f32
set NMLINK=nmlink5
set NMOBJ=.
rem ******* End Check this ********
set INCLUDE=%f77home%\include
set LIB=%f77home%\lib
set F77PATH=%f77home%\bin
set F77EXE=fl32
set F77OPT=/Ox /Op
rem also consider F77OPT=/G4 /Ox /Op
goto nmlink
:nmlink
rem ******* Check this ************
rem Check nmlink*.exe matches this name (ms and df compilers only)
rem Look in e.g. c:\nmv\util to see which filename you have
rem df users who want to use Extended WFN will need nmlinkdf
rem Don't add .exe to the variable name
if '%nmlink%==' set NMLINK=nmlink5
rem ******* End Check this ********
:notwot
set WATCOM=
set NMOS=*
goto set
:wc
rem ******* Check this ************
rem set F77HOME=c:\watcom
rem ******* End Check this ********
set NMBIN=bin
set F77EXE=wfl386
set INCLUDE=
set LIB=%f77home%\lib386
set F77PATH=%f77home%\binw
if '%OS%=='Windows_NT set F77PATH=%f77home%\binnt
set FINCLUDE=%f77home%\src\fortran
set DOS4G=quiet
set WATCOM=%f77home%
set NMOS=dos
set F77OPT=-tr -ox -5 -fp5
rem ****************************************
if '%nmobj%=='non set F77OPT=-tr -od
if '%nmobj%=='std set F77OPT=-tr -ox -5 -fp5
if '%nmobj%=='on0 set F77OPT=-tr -on
if '%nmobj%=='om0 set F77OPT=-tr -om
if '%nmobj%=='op0 set F77OPT=-tr -op
if '%nmobj%=='onf set F77OPT=-tr -on -5 -fp5
if '%nmobj%=='omf set F77OPT=-tr -om -5 -fp5
if '%nmobj%=='opf set F77OPT=-tr -op -5 -fp5
if '%nmobj%=='zp0 set F77OPT=-tr -ob -oi -ol -op -ot -odo
if '%nmobj%=='zpf set F77OPT=-tr -ob -oi -ol -op -ot -odo -5 -fp5
if '%nmobj%=='xp0 set F77OPT=-tr -ox -op
if '%nmobj%=='xpf set F77OPT=-tr -ox -op -5 -fp5
rem ****************************************
:set
set NMCTL=.ctl
set NMOUT=.ls
set NMTBL=.fit
set NMLOG=.lg
set NMDIR=.%nmobj%
if '%nmobj%=='. set NMDIR=.%f77typ%
set NMAWK=gawk
set NMEVAL=9999
rem ***** avoid /noe or other link options ***
set LINK=
if not '%nmauto%==' goto path
set ORGPATH=%path%
set NMAUTO=1
:path
if not '%gnupath%==' set F77PATH=%f77path%;%gnupath%
rem Setting path does not work if there are blanks in path for Win9*
set PATH=%wfnhome%\bin;%f77path%;%nmhome%;%nmhelp%;%orgpath%
if '%tmp_qt%=='-q goto over
echo WFNHOME=%wfnhome%
echo NMHOME =%nmhome%
echo F77HOME=%f77home%
echo OS =%os%
echo F77TYP =%f77typ%
echo F77EXE =%f77exe%
echo F77OPT =%f77opt%
echo NMCTL =%nmctl%
echo NMOUT =%nmout%
echo NMTBL =%nmtbl%
echo NMLOG =%nmlog%
echo NMDIR =%nmdir%
echo NMOBJ =%nmobj%
echo NMAWK =%nmawk%
goto echo%f77typ%
:echog77
:echoh77
echo LIBRARY_PATH=%library_path%
goto over
:echowc
echo NMOS =%nmos%
echo WATCOM =%watcom%
goto over
:echodf
:echoms
echo NMNM =%nmnm%
echo NMTR =%nmtr%
echo NMBIN =%nmbin%
echo NMLINK =%nmlink%
:over
set tmp_qt=
_______________________________________________________