Dear nmusers,
I am planning to analyze categorical PD data from rats in order to make
predictions for an effective concentration in humans. As I have never
analyzed this type of data, I was hoping to get some help from some of the
more experienced modellers.
I have PK data available after intravenous drug administration as well as
after administration of four different oral or s.c. doses, respectively,
from some animals but not all. The PK can be described with a
two-compartment model. Concerning the PD data, I have three different
categories: no response, partial response, full response, available for
both the oral as well as the s.c. route. Thus, the PD data looks like
this:
PD category
dose (mg/kg) full response (%) partial response (%) no
response (%)
0.5 0 0 100
0.75 17 0 83
1 33 17 50
1.5 50 50 0
The percent value means how many animals of the whole group show the
respective response.
My question is if it is possible to obtain a pharmacodynamic parameter
such as an IC50 value from this type of data or if the information is
insufficient. If that is the case, what kind of information can I get from
this type of data? Any suggestions, including NONMEM control streams and
information about the dataset creation (anything special there?) would be
highly appreciated. One equestion that came to my mind was also whether it
would be possible to treat one category as continuous in the sense that
clearly, with higher concentrations, a lot more animals showed the full
response? If it is possible, how would I implement this?
Thanks and best wishes
Nele
_________________________
Dr. Nele Plock
Bayer Schering Pharma AG
Drug Metabolism & Pharmacokinetics
Development Pharmacokinetics
Scientific Expert Development Pharmacokinetics
D- 13342 Berlin
Phone : +49-30-468 15146
Fax: +49-30-468 95146
[EMAIL PROTECTED]
http://www.bayerscheringpharma.de
Vorstand: Arthur J. Higgins, Vorsitzender | Werner Baumann, Andreas Busch,
Ulrich Köstlin, Kemal Malik, Gunnar Riemann
Vorsitzender des Aufsichtsrats: Werner Wenning
Sitz der Gesellschaft: Berlin | Eintragung: Amtsgericht Charlottenburg 93
HRB 283
help with modelling of categorical response data
Hi Nele,
It is not clear from your e-mail whether you have longitudinal PD data (with several observations for the same animal) or just one overall summary per animal. For longitudinal data, you can try to build a model of probability of (ordered categorical three-level no/partial/yes) response versus concentration or concentration in the effect compartment (if you have delay in response relative to exposure). If you have just one PD observation per animal, you need to explore dependence of response on some PK parameter (Cmax, AUC, time above minimum effective concentration, etc.) rather than on concentration.
As to the model, proportional odds model is an obvious candidate for this type of data: you first solve PK, compute concentration-time or some summary PK parameter, and then fit the PK-PD proportional odds model. Proportional odds code can be found in many places, I attached the code that I used. If you use it, you need to assign
DV=2 for no response
DV=1 for partial response
DV=0 for full response
(in may case, the PD effect was manifested as decrease of the score from some baseline level, e.g. 2, to zero).
Note that convergence strongly depends on initial values, you need to assign them as close to the solution as you can guess.
Given the model, you can explore probability of response (full or partial) versus PK, and try to extrapolate to humans (this is a big step, I am not sure how reliable could be this extrapolation)
Leonid
--------------------------------------
Leonid Gibiansky, Ph.D.
President, QuantPharm LLC
web: www.quantpharm.com
e-mail: LGibiansky at quantpharm.com
tel: (301) 767 5566
-------------------------------------
$PRED
CE=PROP ; define exposure: concentration, AUC or anything else
;PD
EMAX=THETA(1)*EXP(ETA(1))
EC50=THETA(2)*EXP(ETA(2))
EFF=EMAX*CE/(EC50+CE)
; Baseline odds
B0=THETA(3)+ETA(3) ; baseline odds that response is full
B1=B0+THETA(4) ; baseline odds that response is full or partial
;LOGITS FOR Y<=2, Y<=1
A0=B0 + EFF ; odds that response is full
A1=B1 + EFF ; odds that response is full or partial
IF (A0.GT.25) A0=25
IF (A1.GT.25) A1=25
C0=EXP(-A0)
C1=EXP(-A1)
;CUMULATIVE PROBABILITIES
P0=1/(1+C0) ; probability that response is full
P1=1/(1+C1) ; probability that response is full or partial
; P(Y=M)
PR2 = (1 -P1) ; probability of no response
PR1 = (P1-P0) ; probability that response is partial
PR0 = P0 ; probability that response is full
IF (DV.EQ.0) Y=PR0
IF (DV.EQ.1) Y=PR1
IF (DV.EQ.2) Y=PR2
; compute score with maximum probability (to compare with observation?)
SMAX = 0
PMAX = PR0
IF(PR1.GT.PMAX) THEN
SMAX=1
PMAX=PR1
ENDIF
IF(PR2.GT.PMAX) THEN
SMAX=2
PMAX=PR2
ENDIF
$EST MAXEVAL=9999 SIGDIG = 4 METHOD=1 LIKE LAPLACE NUMERICAL NOABORT
[EMAIL PROTECTED] wrote:
> Dear nmusers,
>
> I am planning to analyze categorical PD data from rats in order to make predictions for an effective concentration in humans. As I have never analyzed this type of data, I was hoping to get some help from some of the more experienced modellers.
>
> I have PK data available after intravenous drug administration as well as after administration of four different oral or s.c. doses, respectively, from some animals but not all. The PK can be described with a two-compartment model. Concerning the PD data, I have three different categories: no response, partial response, full response, available for both the oral as well as the s.c. route. Thus, the PD data looks like this:
>
> PD category
>
> dose (mg/kg) full response (%) partial response (%) no response (%)
>
> 0.5 0 0 100
> 0.75 17 0 83
> 1 33 17 50
> 1.5 50 50 0
>
> The percent value means how many animals of the whole group show the respective response.
>
> My question is if it is possible to obtain a pharmacodynamic parameter such as an IC50 value from this type of data or if the information is insufficient. If that is the case, what kind of information can I get from this type of data? Any suggestions, including NONMEM control streams and information about the dataset creation (anything special there?) would be highly appreciated. One equestion that came to my mind was also whether it would be possible to treat one category as continuous in the sense that clearly, with higher concentrations, a lot more animals showed the full response? If it is possible, how would I implement this?
>
> Thanks and best wishes
> Nele
> _________________________
> Dr. Nele Plock
> Bayer Schering Pharma AG
> Drug Metabolism & Pharmacokinetics
> Development Pharmacokinetics
> Scientific Expert Development Pharmacokinetics
> D- 13342 Berlin
>
> Phone : +49-30-468 15146
> Fax: +49-30-468 95146
> [EMAIL PROTECTED]
> http://www.bayerscheringpharma.de
>
> Vorstand: Arthur J. Higgins, Vorsitzender | Werner Baumann, Andreas Busch, Ulrich Köstlin, Kemal Malik, Gunnar Riemann
>
> Vorsitzender des Aufsichtsrats: Werner Wenning
>
> Sitz der Gesellschaft: Berlin | Eintragung: Amtsgericht Charlottenburg 93 HRB 283