From: majid.vakily@tap.com
Subject: [NMusers] Cone shaped DV-PRED
Date: Wed, April 20, 2005 4:58 pm
I have been working on a drug with a complex absorption profile. I have
used 2 compartment model with first order input and output (ADVAN4,TRANS1)
and the estimated population parameters, individual estimates, and
estimates of interindividual and residual variability values are
reasonable. However, the population DVs often go as high as
~120 ng/L, population predictions never exceeds 35-45 ng/mL, resulting in a
truncated, cone-shaped DV vs PRED plot. As I indicated the DV vs IPRED
values appear to be fine. I have approximately 5 samples/patient (over 300
patients in the index set). Considering the complex nature of absorption
for this drug with a slow early phase (0.25 to 0.5 hour postdose) and a
rapid phase, I decided to use series of absorption compartments to mimic
the shape of the plasma concentration-time curve during the absorption
phase and capture the Cmax. However, the program is running very slow and
I am not sure this is expected or I have a fundamental error in my codes. I
appreciate input about this issue or any other suggestions which may
improve the fit.
$PROB RUN# 1 OUR TEXT
$INPUT C STDY=DROP SOUD=DROP ID CMT=DROP DATE TIME AMT DV TYPE=DROP EVID SS
II
UT=DROP AGE=DROP BMI=DROP RACE=DROP ALC=DROP SMK=DROP HTEN=DROP DBET=DROP
CAD=DROP DOSE=DROP ALB=DROP ALT=DROP BIL=DROP CRCL=DROP ACEI=DROP ACT=DROP
ASA=DROP DRTC=DROP STER=DROP IRON=DROP NSDS=DROP PPI=DROP SSRI=DROP
DCDT=DROP RSND=DROP COM1=DROP
$DATA POPPKASO1.csv IGNORE=C
$SUBROUTINES ADVAN6 TRANS1 TOL=3
$MODEL
NCOMP=5 NPAR=14
COMP=(DEPOT DEFDOSE) ;GUT COMPARTMENT FOR PARENT DRUG
COMP=(GUT NODOSE);GI COMPARTMENT 2 FOR PARENT DRUG
COMP=(GUT NODOSE);GI COMPARTMENT 3 FOR PARENT DRUG
COMP=(CENTRAL DEFOBS NODOSE);CENTRAL COMPARTMENT FOR PARENT DRUG
COMP=(PERIPH NODOSE) ;PERIPHERAL COMPARTMENT FOR PARENT DRUG
$PK
TVCL=THETA(1)
CL=TVCL*EXP(ETA(1))
TVV4=THETA(2)
V4=TVV4*EXP(ETA(2))
TVKA=THETA(3)
KA=TVKA*EXP(ETA(3))
TVV5=THETA(4)
V5=TVV5*EXP(ETA(4))
TVQ=THETA(5)
Q=TVQ*EXP(ETA(5))
TVMT=THETA(6)
MT=TVMT*EXP(ETA(6))
Kel=CL/V4
K45=Q/V4
K54=Q/V5
KT=3/MT
S4=V4/1000
$DES
DADT(1)=-KT*A(1)
DADT(2)=KT*A(1)-KT*A(2)
DADT(3)=KT*A(2)-KA*A(3)
DADT(4)=KA*A(3)+K54*A(5)-Kel*A(4)-K45*A(4)
DADT(5)=K45*A(4)-K54*A(5)
$ERROR
Y=(A(4)/V4)*(1+ERR(1))+ERR(2)
DEL=0
IF (F.EQ.0) DEL=1
IPRED=F
W=IPRED+DEL
IRES=DV-IPRED
IWRES=IRES/W
$THETA
(15, 150, 1500) ;[CL]
(3, 200, 2000) ;[V4]
(0.1, 1, 100) ;[KA]
(3, 800, 8000) ;[V5]
(10, 100, 3000) ;[Q]
(0.01, 0.25, 2.5) ;[MT]
$OMEGA
0.5 ;[CL]
1 ;[V4]
0.5 ;[KA]
1 ;[V5]
1 ;[Q]
0.4 ;[MT]
$SIGMA
0.4 ;[PROPORTIONAL]
4 ;[ADDITIVE]
$EST MAXEVAL=9999 MSF=1.msf PRINT=5 NOABORT METHOD=0 POSTHOC
$COVARIANCE
$TABLE ID TIME IPRED CL V4 Q V5 KA MT AUC T50 NOPRINT ONEHEADER FILE=1.TAB
Thanks,
Majid Vakily, Ph.D.
Senior Research Investigator
Department of Drug Metabolism & Pharmacokinetics
Phone: (847) 582-2198
Fax; (847) 582-2388
Cone shaped DV-PRED
From: bulitta@ibmp.osn.de
Subject: Re: [NMusers] Cone shaped DV-PRED
Date: Wed, April 20, 2005 9:48 pm
Dear Dr Vakily,
One proposal to model your data would be to dose a zero order input into the gut
compartment with first order absorption from the gut into the central compartment.
You might add more flexibility to the absorption process by adding a lag-time for
the zero-order input. It is questionable, whether this model has a real mechanistic
interpretation. However, you can use e.g. ADVAN 2 / 4 / 12, and thus it is very
fast.
I am not sure, if your data (5 points per profile) allow to estimate all the
parameters and their between subject variability (BSV). From my experience,
especially BSV on the duration (TK0) of the zero order input may become difficult. I
usually do not include BSV on TK0, unless it really improves the predictive
performance. I noticed a tendency that the predictive performance was better, with a
BLOCK structure for the OMEGAs of the absorption parameters.
After Nick showed me how to do this, I was happy to test this model and a series of
others on about 10 drugs with complex absorption characteristics (solubility limit,
active transporters, pH-dependent lipophilicity (Log D) etc.). Maybe it only worked,
since I had at least 10 data points per profile. However, it might be worth to give
it a try.
I would recommend to start with a one-compartment disposition model to get
reasonable estimates for the absorption parameters (and their variability) and then
add more disposition compartments, if required. I got this model to work with three
disposition compartments with convincing predictive performance. However, if the
initials for the absorption parameters are really bad, there is a good chance that
this model fails completely.
If you still experience an insufficient predictive performance in the "Cmax region",
I would try the "sequential independent zero and then first order absorption model"
described in Nicks paper below.
Please find two papers on complex absorption models and the control stream below.
Hope this helps.
Best wishes
Juergen
----------------------------------------------------
Juergen Bulitta, M.Sc.
Research Scientist
IBMP - Institute for Biomedical and Pharmaceutical Research
Paul-Ehrlich-Strasse 19
90562 Nurnberg - Heroldsberg
Germany
----------------------------------------------------
Holford, N. H., R. J. Ambros, and K. Stoeckel. 1992. Models for describing
absorption rate and estimating extent of bioavailability: application to cefetamet
pivoxil. J Pharmacokinet Biopharm 20:421-42.
Piotrovskij, V. K., G. Paintaud, G. Alvan, and T. Trnovec. 1994. Modeling of the
saturable time-constrained amoxicillin absorption in humans. Pharm Res 11:1346-51.
$PROBLEM Zero order input into the gut compartment
$INPUT ID TIME AMT RATE CMT EVID DVID DV
$DATA ../Data/Raw_data.csv IGNORE=#
$ESTIM MAXEVAL=9999 NOABORT PRINT=1
METHOD=COND INTERACTION SLOW SIG=5
$COV
$SUB ADVAN4 TRANS4
$THETA (0,10) ;POP_CLT unit L/h total body clearance
$THETA (0,20) ;POP_V1 unit L volume of central compartment
$THETA (0,100) ;POP_V2 unit L volume of peripheral compartment
$THETA (0,10) ;POP_CLD2 unit L/h intercompartmental clearance
$THETA (0,15) ;POP_TABS unit min half-life of absorption from gut into central
compartment
$THETA (0,36) ;POP_TK0 unit min duration of zero order input into the gut
compartment
$THETA (0,12) ;POP_TLAG unit min lag time for the zero order input into the gut
$OMEGA 0.05 ; BSVCLT
$OMEGA 0.08 ; BSVVSS
$OMEGA BLOCK(3)
0.2 ; BSVTK0
0.01 0.01 ; BSVTABS
0.01 0.01 0.3 ; BSVLAG
$SIGMA 0.01 ;cvcp
$SIGMA 0.001 ;sdcp
$PK
CL = POP_CLT*EXP(BSVCLT)
V2 = POP_V1*EXP(BSVVSS)
V3 = POP_V2*EXP(BSVVSS)
Q = POP_CLD2
TABS = POP_TABS*EXP(BSVTABS)
KA = LOG(2)/(TABS/60)
S2 = V2
Tk0 = POP_Tk0*EXP(BSVTK0)
D1 = TK0/60
TLAG = POP_TLAG*EXP(BSVLAG)
ALAG1 = TLAG/60
$ERROR
CP=F
Y=CP*(1+CVCP)+SDCP
$TABLE ID TIME AMT CMT EVID DVID CL V2 V3 KA TK0 Y
ONEHEADER NOPRINT FILE=Zero_order_input_into_gut.fit
#########################
raw_data.csv example
#ID,TIME,AMT,RATE,CMT,EVID,DVID,DV
1,0,800,-2,1,1,0,.
1,0,.,.,.,2,1,.
1,0.167,.,.,.,2,1,.
1,0.333,.,.,.,0,1,0.12
1,0.5,.,.,.,0,1,0.95
1,0.75,.,.,.,0,1,1.5
1,1,.,.,.,0,1,2.6
1,2,.,.,.,0,1,7.2
1,3,.,.,.,0,1,13.5
1,4,.,.,.,0,1,12.2
1,6,.,.,.,0,1,11.2
1,8,.,.,.,0,1,10.3
1,12,.,.,.,0,1,7.92
1,16,.,.,.,0,1,5.51
1,24,.,.,.,0,1,2.98
1,36,.,.,.,0,1,0.82
1,48,.,.,.,0,1,0.25
################################
_______________________________________________________