Re: PRED capped
Hi Markus,
I assume that by "capped" you mean that there is one value that shows up
repeatedly as the maximum value.
Given your model below without seeing the data, there are no covariates in the
model to allow for differences between individuals without etas (that come with
IPRED). If you are observing the capping with this and not a previous dataset,
then I would guess that you only have one dose amount in this file (like 50 mg)
and that you may have had more unique dose amounts in the previous run.
If that doesn't explain it, could you post the current and previous data files?
Thanks,
Bill
Quoted reply history
On Feb 22, 2014, at 22:09, "markus joerger"
<[email protected]<mailto:[email protected]>> wrote:
dear community,
I use a previously validated model of capecitabine in a new data-set. While the
model converges successfully, PRED for all metabolites/compartments are
'capped' for PRED (at 1.6 for compartment 2, 2.4 for compartment 3, 3.0 for
compartment 4 and 1.2 for compartment 5). At the same time, IPRED's are not
'capped', and GoF look nice. In a previous data-set using the same model, this
phenomenon did not occur.
Any suggestion is very wellcome,
best regards
Markus
Control stream (capecitabine = compartment 2, DFCR = compartment 3, DFUR =
compartment 4, 5FU = compartment 5):
$PROB RUN# 001
$INPUT C ID TIME AMT DV CMT MDV EVID STUDY NR SEX AGE LIVERM WT BSA
PS BILI Krea ASAT ALAT T85C A496G G1601A A1627G T1896C EXON14S A2846T
C24T G1249A A4145G C4488T GSTT1 GSTP1 GSTM1 TSTR TS3CG TYMSPHENO TS3UTR
MTHFR ERCC1 XRCC1 GSTP1B GASTRECT
$DATA cap5.CSV IGNORE=C
$SUBROUTINES ADVAN6 TOL=6
$MODEL
NCOMPARTMENTS=5
COMP=(DOS)
COMP=(CAP)
COMP=(DFCR)
COMP=(DFUR)
COMP=(5FU)
$PK
TVKA=THETA(1)
KA=TVKA*EXP(ETA(1)) ;absorption rate constant.1
TVV2=THETA(2)
V2=TVV2*EXP(ETA(2)) ;CAP distribution volume.2
TVV3=THETA(3)
V3=TVV3*EXP(ETA(3)) ;DFCR distribution volume.3
TVV4=THETA(4)
V4=TVV4*EXP(ETA(4)) ;DFUR distribution volume.4
TVV5=THETA(5)
V5=TVV5*EXP(ETA(5)) ;5FU distribution volume.5
TVQ1=THETA(6)
Q1=TVQ1*EXP(ETA(6)) ;CAP > DFCR.6
TVQ2=THETA(7)
Q2=TVQ2*EXP(ETA(7)) ;DFCR > DFUR.7
TVQ3=THETA(8)
Q3=TVQ3*EXP(ETA(8)) ;DFUR > 5FU.8
TVCL1=THETA(9)
CL1=TVCL1*EXP(ETA(9)) ;CL1-CAP.9
TVCL2=THETA(10)
CL2=TVCL2*EXP(ETA(10)) ;CL2-5FU.10
ALAG1=THETA(11)*EXP(ETA(11)) ;ALAG1.11
F1=0.95
S2=V2/1000
S3=V3/1000
S4=V4/1000
S5=V5/1000
K23=Q1/V2
K34=Q2/V3
K45=Q3/V4
K20=CL1/V2
K50=CL2/V5
$ERROR CALLFL=0
IPRE=-3
FLG2=0
FLG3=0
FLG4=0
FLG5=0
IF(CMT.EQ.2)FLG2=1
IF(CMT.EQ.3)FLG3=1
IF(CMT.EQ.4)FLG4=1
IF(CMT.EQ.5)FLG5=1
IF(F.GT.0) IPRE=LOG(F)
Y=LOG(F)+EPS(1)*FLG2+EPS(2)*FLG3+EPS(3)*FLG4+EPS(4)*FLG5
W=1
IRES=DV-IPRE
IWRES=IRES/W
$DES
DADT(1) = -KA*A(1)
DADT(2) = KA*A(1)-K23*A(2)-K20*A(2)
DADT(3) = K23*A(2)-K34*A(3)
DADT(4) = K34*A(3)-K45*A(4)
DADT(5) = K45*A(4)-K50*A(5)
$THETA
(0,16) ;KA.1
(0,580) ;V-CAP.2
1 FIX ;V-DFCR.3
1 FIX ;V-DFUR.4
1 FIX ;V-5FU.5
(0,24) ;CAP > DFCR.6
(0,16) ;DFCR > DFUR.7
(0,8) ;DFUR > 5FU.8
(0,180) ;CL1-CAP.9
(0,75) ;CL2-5FU.10
(0,0.2) ;ALAG1.11
$OMEGA
0.14 ;KA.1
0 FIX ;V-CAP.2
0 FIX ;V-DFCR.3
0 FIX ;V-DFUR.4
0.14 ;V-5FU.5
0.14 ;CAP > DFCR.6
0.14 ;DFCR > DFUR.7
0.14 ;DFUR > 5FU.8
0.14 ;CL1-CAP.9
0.14 ;CL2-5FU.10
0 FIX ;ALAG1.11
$SIGMA
0.14 ;CMP2
0.14 ;CMP3
0.14 ;CMP4
0.14 ;CMP5
$ESTIMATION PRINT=5 MAXEVAL=5000 METHOD=1 INTER
NOABORT POSTHOC SIGDIG=3 MSFO=MSF020B
$COVARIANCE MATRIX=R
$TABLE ID TIME AMT CMT IPRE IWRES
CL1 CL2 V2 V3 V4 V5 NOPRINT ONEHEADER FILE=cap8.TAB
--
Markus Joerger MD-PhD ClinPharm
Medical Oncology&Clinical Pharmacology
Department of Internal Medicine
Kantonsspital
St. Gallen
Switzerland
[email protected]<mailto:[email protected]>
Phone: +41-765591070
Fax: +41-714946325