Re: time-dependent clearance model
Xiaofeng,
Such a large difference suggests you may have a problem with units:
check AMT, DV, and the parameter S2 for consistency.
A couple of other points:
- If the full induction is expected by day 7, and you only have data
on day 1 and after day 7, you may not be able to estimate KIN. You
may be better off with the model where there is CLI on day 1 and
CLSS on days >1 (And you will not need $DES for that model).
- You have 6 observations per subject and you have 7 ETAs, it is too
many, your model should be overparameterized (Check whether relative
standard errors are large).
Regards,
Katya
Ekaterina Gibiansky, Ph.D.
CEO&CSO, QuantPharm LLC
Web: www.quantpharm.com
Email: EGibiansky at quantpharm.com
On 3/4/2012 5:33 PM, Wang, Xiaofeng wrote:
Dear nmusers,
I have a drug with clearance autoinduction.
I have sparse data(three observations on day 1, two between
day 7 and 14, and one on day 28). I am trying to run a
time-dependent clearance model. I tried FO and FOCEI, but I
always got unreasonable estimate for the initial clearance
(CLI) which is about 0.15 L/h (from knowledge of previous
studies, the reasonable initial clearance should be around 20
L/h and maximum induction occurs around day 7). Could someone
give me some advice about my model and my data? Thank you.
Xiaofeng
The CTL file:
$PROB
$INPUT C ID TIME AMT DV MDV EVID ADDL II
CMT
$DATA C:/ IGNORE=C
$SUBROUTINES ADVAN6 TOL=6
$MODEL NCOMPARTMENTS=3
COMP=(DEPOT,DEFDOSE)
COMP=(CENTRAL,DEFOBS)
COMP=(PERIP)
$PK
CLI=THETA(1)*EXP(ETA(1))
CLSS=THETA(2)*EXP(ETA(2))
KIN=THETA(3)*EXP(ETA(3))
V2= THETA(4)*EXP(ETA(4))
Q= THETA(5)*EXP(ETA(5))
V3= THETA(6)*EXP(ETA(6))
KA= THETA(7)*EXP(ETA(7))
S2=V2
K23=Q/V2
K32=Q/V3
$DES
CL=CLSS-(CLSS-CLI)*EXP(-KIN*T)
K20=CL/V2
DADT(1)=-KA*A(1)
DADT(2)=KA*A(1)+K32*A(3)-K23*A(2)-K20*A(2)
DADT(3)=K23*A(2)-K32*A(3)
$ERROR
IPRE=LOG(1)
IF(F.GT.0) IPRE=LOG(F)
Y = IPRE+EPS(1)
$EST METHOD=0 POSTHOC PRINT=10 MAX=9999
SIG=2 NOABORT MSFO=050.MSF
$THETA
(0, 20);[CLI]
(0, 65);[CLSS]
(0, 0.02) ;[KIN]
(0, 45);[V2]
(0, 5);[Q]
(0, 58);[V3]
(0, 0.2);[KA]
$OMEGA .25 .25 .25 .25 .25 .25 .25
$SIGMA .2
$COV PRINT=E
$TABLE ID TIME DV CLI CLSS KIN V2 Q V3 KA
IPRE CWRES ONEHEADER NOPRINT FILE=050.TAB
$TABLE ID TIME CLI CLSS KIN V2 Q V3 KA
FIRSTONLY NOAPPEND NOPRINT FILE=050.PAR
$TABLE ID ETA1 ETA2 ETA3 ETA4 ETA5 ETA6
ETA7 FIRSTONLY NOAPPEND NOPRINT FILE=050.ETA
$TABLE ID TIME CLI CLSS KIN V2 Q V3 KA
FIRSTONLY NOAPPEND NOPRINT FILE=PATAB050