Question about model validity and identifiability
Hello -
I have a question regarding identifiability of my model parameters and I
was looking for a little guidance. I am modeling an oral drug and its
metabolite that are interconvertible with one another and the parent
undergoes enterohepatic recirculation. Although I initially attempted
to model the interconversion of parent and metabolite in the central
compartment, I have found that the model that best describes the data is
such that the parent and the metabolite share a peripheral compartment
(thus allowing for interconversion). In the central compartment,
therefore, I am making the assumption that the metabolite formation is
dependent upon the clearance of the parent (that is, I am estimating
Clm/Fm where Fm is the fraction of the parent converted to the
metabolite). However, this leads me to question whether or not this
model structure is valid, as this allows for formation of the metabolite
via the peripheral compartment in addition to the (irreversible)
formation from the central compartment. Hence, I'm unsure if the model
parameters are properly identifiable. Any insight on this matter would
be greatly appreciated; I have included my control file below for you
information.
Thanks for your assistance -
Al Berg
$SUBROUTINES ADVAN6 TRANS1 TOL=9
$MODEL NCOMP=5
COMP=(ABSORB)
COMP=(CENTRAL); parent drug central
COMP=(MET); Metabolite central
COMP=(EHR); Bile compartment
COMP=(PERIPH); shared parent-metabolite peripheral compartment
$PK
IF(AMT.GT.0)PODO=AMT
KA1=THETA(1)*EXP(ETA(1))
BIO=1 ;bioavailability fixed as 1 as this is the reference formulation
MTT=THETA(2)*EXP(ETA(2));mean transit time to absorption compartment
N=THETA(3)*EXP(ETA(3));number of transit compartments
F1=0; Since estimating from BIO
CL=THETA(4)*EXP(ETA(4)); clearance of parent
V=THETA(5)*EXP(ETA(5)); volume of parent
CL30=THETA(6)*EXP(ETA(6)); clearance of metabolite
V3=THETA(7)*EXP(ETA(7)); volume of metabolite
CL24=THETA(8)*EXP(ETA(8)); clearance from parent to EHR
K41=THETA(9)*EXP(ETA(9)); release from EHR comp
MTIME(1)=THETA(10)*EXP(ETA(10)); EHR start time
MTIME(2)=MTIME(1)+THETA(11)*EXP(ETA(11)); EHR end time
CL25=THETA(12)*EXP(ETA(12)); clearance from parent to peripheral comp
CL35=THETA(13)*EXP(ETA(13)); clearance from metabolite to peripheral
comp
V5=THETA(14)*EXP(ETA(14)); volume of peripheral comp
S2=V
S3=V3
K12=KA1
K20=CL/V
K24=CL24/V
K25=CL25/V
K30=CL30/V3
K35=CL35/V3
K53=CL35/V5
K52=CL25/V5
KTR=(N+1)/MTT
LNFAC=LOG(2.5066)+(N+0.5)*LOG(N)-N ;log transformation of the stirling
approximation
$DES
DL=1/100000
FLAG=MPAST(1)-MPAST(2)
DADT(1)=EXP(LOG(BIO*PODO+DL)+LOG(KTR+DL)+N*LOG(KTR*T+DL)-KTR*T-LNFAC)-K1
2*A(1)+FLAG*K41*A(4)
DADT(2)=K12*A(1)-(K25+K20+K24)*A(2)+K52*A(5); parent central
DADT(3)=K20*A(2)-(K35+K30)*A(3)+K53*A(5); metabolite central
DADT(4)=K24*A(2)-FLAG*(K41)*A(4); EHR back into absorption compartment
DADT(5)=K25*A(2)+K35*A(3)-(K52+K53)*A(5); shared peripheral compartment
$ERROR
DEL=0
IF (F.LE.0.0001) DEL=1
IPRE=F
W1= F
W2= 1
IRES= DV-IPRE
IWRE=IRES/(W1+W2)
Y = F + W1*ERR(1) + W2*ERR(2)
$THETA
;TRANSIT
(0, .4) ; KA1 ;1/h
(0, 1) ; MTT ; h
(0, 10) ; N ;
;CENTRAL
(0, 10) ; CL ; L/h
(0, 5) ; V ; L
;SID
(0, 1) ; CL30 ; L/h
(0, 3) ; V3 ; L
;EHR_SID
(0, 5) ; CL24 ; L/h
(0, 1) ; K41 ; 1/h
(2, 6, 12) ; MTIME1 ; h
(0, .1, 5) ; DURATION ; h
;PERIPHERAL
(0, 10) ; CL25 ;L/h
(0, 40) ; CL35 ;L/h
(0, 300) ; V5 ; L