Re: Unix to Windows Model Translation / PK Comp Initialization
Hi Josh,
I am not sure what causes your problem, but the control stream is not completely correct. I would move
WB=(1-EXP((-(KA1*TIME)**GAMA1)))*KAM
to the $DES block, as
WB=(1-EXP((-(KA1*T)**GAMA1)))*KAM
(TIME is the value of time at the event records while T is the internal running time that is used for the differential equations: my understanding that you need to use T, not TIME)
In your current version, WB is constant between records, while actually it should be time-dependent.
What are you PK doses? DO you implement the input via WB only or you have extra doses? I do not think that it is correct to initialize A(2) with 1 if you do not have IV dose=1 at TIME=0.
Leonid
--------------------------------------
Leonid Gibiansky, Ph.D.
President, QuantPharm LLC
web: www.quantpharm.com
e-mail: LGibiansky at quantpharm.com
tel: (301) 767 5566
[EMAIL PROTECTED] wrote:
> Dear NONMEM Users,
>
> We have recently run into a rather puzzling problem with a PK/PD model and are hoping one of the NONMEM experts in the community can provide some insight. The model was originally developed, and ran well, using a previously used Unix-based version of NONMEM. However, when we attempted to re-implement the model with our current, windows-based NONMEM VI, the model would not run, giving a numerical difficulties error. The bones of the model are provided below:
>
> $MODEL NCOMP=5
> COMP(DEPOT,DEFDOSE)
> COMP(CENTRAL)
> COMP(PD1)
> COMP(PD2)
> COMP(PD3,DEFOBS)
>
> $PK
> "FIRST
> " COMMON /PRCOMG/ IDUM1,IDUM2,IMAX,IDUM4,IDUM5
> " INTEGER IDUM1,IDUM2,IMAX,IDUM4,IDUM5
> " IMAX=1000000
>
> KA1=KAIN
>
> GAMA1=GAMA
> ALAG1=LAGI
> V=VIND
> CL=CLIN
> KAM=KAMI
> WB=(1-EXP((-(KA1*TIME)**GAMA1)))*KAM
> K20=CL/V
> S2=V/1000
>
> BETA=0.00000003
> PROD=1.736
> V0=VIN0
> TD=0.0001
>
> DELT=THETA(1)*EXP(ETA(1))
> CV=THETA(2)*EXP(ETA(2))
> IC50=THETA(3)*EXP(ETA(3))
> HG=THETA(4)*EXP(ETA(4))
>
> T0=(DELT*CV)/(BETA*PROD)
>
> SYN=T0*(TD+(BETA*V0))
>
> F3=T0
> F4=(CV*V0)/PROD
> F5=V0
>
> $DES
> DADT(1)=-WB*A(1)
> DADT(2)=WB*A(1)-K20*A(2)
> C2=A(2)*1000/V
>
> EFF=(C2**HG/(IC50**HG+C2**HG))
>
> DADT(3)=SYN-A(3)*TD-BETA*A(3)*A(5)
> DADT(4)=BETA*A(3)*A(5)-DELT*A(4)
> DADT(5)=(1-EFF)*PROD*A(4)-CV*A(5)
>
> The PK parameters are fixed in the model. In order to get the model to run with our current version of NONMEM, we had to initialize the CENTRAL compartment with a nominal value (i.e. 1). This was done by modifying the data set to contain AMT=1 for CMT=2 at TIME=0 for each subject. The results obtained following this modification are in agreement with those obtained previously with the original model run in Unix.
>
> Has anyone run into a similar situation when running Unix-developed models in a windows environment? Has anyone ever encountered a situation where it was necessary to initialize a PK compartment?
>
> Any insight into this problem would be greatly appreciated.
>
> Regards,
> Josh