Re: Weibull distribution
Steve makes a good point. You should be using the special variable T in $DES
not TIME. T is the instantaneous value of time used by the DE solver. TIME is
the time of the current record which the DE solver is attempting to move
towards to find a solution.
Try this for DADT(1):
DADT(1)=-A(1)*(BETA/ALPHA)*((T/ALPHA)**(BETA-1))*EXP(-(T/ALPHA)**BETA)
Nick
Steve Troy wrote:
>
> Dear Abduljalil,
>
> I am not an expert on using the Weibull distribution for drug
> absorption, but I suspect that the value of TIME in the equation for
> DADT(1) should represent the elapsed time since the most recent dose.
> For example, if dosing occurs at 0, 24, and 48 hours, then the
> observation at 25 hours after the start of the study (ie, 1 hour after
> the most recent dose) should use TIME=1 hour in the equation for
> DADT(1). However, I suspect that TIME=25 hours is being used in the
> current problem.
>
> Good luck,
>
> Steve
>
Quoted reply history
> -----Original Message-----
> From: [EMAIL PROTECTED] [mailto:[EMAIL PROTECTED]
> On Behalf Of Khaled Mohammed Abduljalil
> Sent: Wednesday, April 11, 2007 9:15 AM
> To: [email protected]
> Subject: [NMusers] Weibull distribution
>
> Dear NONMEM users,
>
> I have tried to study the pk profiles of a drug after
> multiple oral dosage regimen of 500mg every 12hr. The
> estimation process was well performed with the first dose
> (only) using Weibull function. but if i apply the same
> control file to the whole data (ie, single dose and
> multiple doses), it does not work any more. I can not
> detect my error. Could any one tell me where is it?
> neither first order nor Mich.-Menten models fitted the
> data like weibull model.
>
> thank you very much in advance for your response.
>
> sincerely yours
> Abduljalil
>
> $SUBROUTINES ADVAN6 TRANS1 TOL=3
> $MODEL
> COMP=(DEPOT,DEFDOSE)
> COMP=(CENTRAL,DEFOBS)
>
> $PK
> CL=THETA(1)*EXP(ETA(1))
> V=THETA(2)*EXP(ETA(2))
> BETA=THETA(3)*EXP(ETA(3))
> ALPHA=THETA(4)*EXP(ETA(4))
>
> K=CL/V
>
> S1=1
> S2=V
>
> $ERROR
> DEL=0
> IF(F.EQ.0) DEL=0.001
> W=F
> IPRED=F
> IRES=DV-IPRED
> IWRES=IRES/(W+DEL)
> Y=F+EPS(1)
>
> $DES
> DADT(1)=-A(1)*(BETA/ALPHA)*((TIME/ALPHA)**(BETA-1))*EXP(-(TIME/ALPHA)**B
> ETA)
> DADT(2)=-DADT(1)-A(2)*K
>
> $THETA
> (0.01,17,80);
> (10,115,900);
> (0.1,2.2,30)
> (0.1,2.6,30)
> (0.001,2)
> (0.001,1)
>
> $OMEGA
> 0.1 0.2 0.08 0.2
>
> $SIGMA
> 0.2
>
> $EST METHOD=1 INTER PRINT=5 NOABORT MAXEVAL=9999
> ************************************************************
> The contents of this message are intended only for the use
> of the individual to which they are addressed and may
> contain confidential or privileged information. If you are
> not the intended recipient, you are hereby notified that
> any use, distribution, disclosure or copying of this
> message, any attachment or the information contained
> therein is strictly prohibited. If you have received this
> transmission in error, please notify the original sender
> immediately and delete all copies of this message, along
> with any attachments. Thank you.
> ************************************************************
--
Nick Holford, Dept Pharmacology & Clinical Pharmacology
University of Auckland, 85 Park Rd, Private Bag 92019, Auckland, New Zealand
email:[EMAIL PROTECTED] tel:+64(9)373-7599x86730 fax:373-7556
http://www.health.auckland.ac.nz/pharmacology/staff/nholford/