Dose and concentration unit differences
From: "Gordi, Toufigh" Toufigh.Gordi@cvt.com
Subject: [NMusers] Dose and concentration unit differences
Date: Wed, 28 Sep 2005 14:06:48 -0700
Hi Leonid,
Sorry for the delay in my response to your mail. I was out of office for
a few days and also been working on this problem a little bit. I finally
managed to make the model work by a simple change from ADVAN9 to ADVAN8,
with identical parameter estimates, as suggested by you.
The control stream:
$INPUT ID DATE=DROP TIME AMT DV EVID AGE SEXF WT
CLCR NMS
$DATA LNPK2.csv IGNORE=#
$SUBROUTINE ADVAN9 TRANS1 TOL=5 ; or ADVAN8
$MODEL
NCOMP= 2
COMP = (CENT DEFDOS DEFOBS)
COMP = (PRF1)
$PK
"FIRST
" COMMON /PRCOMG/ IDUM1,IDUM2,IMAX,IDUM4,IDUM5
" INTEGER IDUM1,IDUM2,IMAX,IDUM4,IDUM5
" IMAX=1000000000
SLP=THETA(1)*EXP(ETA(1))
CLNR=THETA(2)
CL=CLNR+SLP*CLCR
VC=THETA(3)*EXP(ETA(2))
CLD2=THETA(4)
V2=THETA(5)
S1=VC
$DES
DADT(1)=-A(1)*CL/VC-A(1)*CLD2/VC+A(2)*CLD2/V2
DADT(2)=A(1)*CLD2/VC-A(2)*CLD2/V2
$ERROR
IPRD = F
IF(IPRD.LE.0) IPRD=0.0001
IPRED=LOG(IPRD)
W = SQRT(THETA(6)**2+THETA(7)**2/IPRD**2)
IRES = DV-IPRED
IWRES = IRES/W
Y = IPRED + W * EPS(1)
$THETA (0, 1) ;1 SLP
$THETA (0, 5) ;2 CLNR
$THETA (0, 14) ;3 VC
$THETA (0, 52) ;4 CLD2
$THETA (0, 37) ;5 V2
$THETA (0, 0.1) ;6 ERROR
$THETA (0 FIX) ;7 ERROR
$OMEGA 0.01 ;1 IIV SLP
$OMEGA 0.01 ;2 IIV VC
$SIGMA 1 FIX
$ESTIMATION NOABORT MAXEVAL=9999 PRINT=10 METHOD=1 INTERACTION
$COVARIANCE
$TABLE ID SLP VC CL NOPRINT ONEHEADER FILE=PATAB121
$TABLE ID TIME IPRED IWRES NOPRINT ONEHEADER FILE=SDTAB121
$TABLE ID SEXF NOPRINT ONEHEADER FILE=CATAB121
$TABLE ID AGE WT CLCR NOPRINT ONEHEADER FILE=COTAB121
Toufigh
_______________________________________________________